games-util/lutris: Bump to version 0.5.7

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Lars Wendler <[email protected]>

games-util/lutris/Manifest

@@ -1,2 +1,3 @@
 DIST lutris_0.5.4.tar.xz 1843880 BLAKE2B f286d62df3bf5a5eadd634d2d177a5b69b5fa5d897e70f58a19be4148609e56ba33c29ce4218ae833dbdf9dded1e9be869f9ed4d84ba2b435a09981219d74438 SHA512 81669f2021063229bad78ebc49b54075058266716279695c53c43a5a06a8c1d4e5a9dcbcb20a1becfe0d243aa6e812f5a30b4d90f418d4cffcff18daefb09c50
 DIST lutris_0.5.6.tar.xz 1747440 BLAKE2B e39206d8245d99a0424537cd9d9ed860c4e0d9fd373afe61d7e19eb2672bee621d541060af74f1197242e49a846e70fe16eb28e0c57370d2e11634d7035ab1fe SHA512 3ac9f7095c30044990e42f671d6e1e5cac6cd921cdf93e175400335cb6e9ae5b1bf8101dc0805838f3c5bf9713b891c62960c80a1a20aef1e4f896a74af97a01
+DIST lutris_0.5.7.tar.xz 2133524 BLAKE2B d27191668f582a5cd50941ca227d6121f1bfdb4824c490dd54cc513fda523712af9480451b0e5503404aba8d083c94ce91b928ed3faf4e94ea9f0bbf28b764c1 SHA512 f751be82dd5550dc882932980a3a04a62f183e5f0dddc9939154025408da081392917834324875a80ae8b354906e04835c2df56c23f1d6d29cd9fbdc514e1c57

games-util/lutris/lutris-0.5.7.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite,threads(+)"
+
+inherit distutils-r1 virtualx xdg
+
+DESCRIPTION="An open source gaming platform for GNU/Linux"
+HOMEPAGE="https://lutris.net/"
+
+if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI="https://github.com/lutris/lutris.git"
+ inherit git-r3
+else
+ SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
+ KEYWORDS="~amd64 ~x86"
+ S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+ app-arch/cabextract
+ app-arch/p7zip
+ app-arch/unrar
+ app-arch/unzip
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-evdev[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ gnome-base/gnome-desktop:3[introspection]
+ media-sound/fluid-soundfont
+ net-libs/libsoup
+ net-libs/webkit-gtk:4[introspection]
+ x11-apps/mesa-progs
+ x11-apps/xgamma
+ x11-apps/xrandr
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify
+"
+
+python_install_all() {
+ local DOCS=( AUTHORS README.rst docs/installers.rst )
+ distutils-r1_python_install_all
+}
+
+python_test() {
+ virtx nosetests -v
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ # Quote README.rst
+ elog "Lutris installations are fully automated through scripts, which can"
+ elog "be written in either JSON or YAML. The scripting syntax is described"
+ elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+ elog "available online at lutris.net."
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+}