media-libs/libsndfile: Security bump to version 1.0.26 (bug #566680).

Package-Manager: portage-2.2.25
Signed-off-by: Lars Wendler <[email protected]>

media-libs/libsndfile/Manifest

@@ -1 +1,2 @@
 DIST libsndfile-1.0.25.tar.gz 1060692 SHA256 59016dbd326abe7e2366ded5c344c853829bebfd1702ef26a07ef662d6aa4882 SHA512 4ca9780ed0a915aca8a10ef91bf4bf48b05ecb85285c2c3fe7eef1d46d3e0747e61416b6bddbef369bd69adf4b796ff5f61380e0bc998906b170a93341ba6f78 WHIRLPOOL 37ef0a66f11d3f60741fe40bce2b255f44284cf78f7c762542def2aab0eefed1360181bb7f29b9850c11e8672a78bc5a687bc04f2cc349e45dfd24721bea8f29
+DIST libsndfile-1.0.26.tar.gz 1080727 SHA256 cd6520ec763d1a45573885ecb1f8e4e42505ac12180268482a44b28484a25092 SHA512 49a131482f9735e2f171ab7b59770cafc6b92e177f88bed9d2e6189390abc5aa473081dce3e4ec3c0e32b6f3d8c19901136b3df15b9222c11b578f522e88257e WHIRLPOOL 30ea43dab113a4e0fd5cf65e340f50943dae2a100a8b029473adb3c21f388d05a7e124d6219b25c22dc29efa3ab24a600eec958b435f7a050129e17d809e89fb

media-libs/libsndfile/libsndfile-1.0.26.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+PYTHON_COMPAT=( python2_7 pypy )
+inherit autotools-multilib flag-o-matic python-any-r1
+
+MY_P=${P/_pre/pre}
+
+DESCRIPTION="A C library for reading and writing files containing sampled sound"
+HOMEPAGE="http://www.mega-nerd.com/libsndfile"
+if [[ "${MY_P}" == "${P}" ]]; then
+	SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
+else
+	SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="alsa minimal sqlite static-libs test"
+
+RDEPEND="
+	!minimal? ( >=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}]
+		>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+		>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	alsa? ( media-libs/alsa-lib )
+	sqlite? ( >=dev-db/sqlite-3.2 )
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r6
+					!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# fix adding largefile flags on amd64 multilib
+	# https://github.com/erikd/libsndfile/commit/d464da7dba4d5
+	sed -i -e 's:AC_SYS_EXTRA_LARGEFILE:AC_SYS_LARGEFILE:' configure.ac || die
+	sed -i -e 's:noinst_PROGRAMS:check_PROGRAMS:' {examples,tests}/Makefile.am || die
+
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-1.0.17-regtests-need-sqlite.patch
+		"${FILESDIR}"/${PN}-1.0.25-make.patch
+	)
+
+	AT_M4DIR=M4 \
+	autotools-multilib_src_prepare
+	epunt_cxx
+}
+
+src_configure() {
+	my_configure() {
+		local myeconfargs=(
+			--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
+			$(use_enable static-libs static)
+			$(use_enable !minimal external-libs)
+			--disable-octave
+			--disable-gcc-pipe
+			)
+
+		if [ "${ABI}" = "${DEFAULT_ABI}" ] ; then
+			myeconfargs+=(
+				$(use_enable alsa)
+				$(use_enable sqlite)
+			)
+		else
+			myeconfargs+=(
+				--disable-alsa
+				--disable-sqlite
+			)
+		fi
+
+		autotools-utils_src_configure
+
+		if [ "${ABI}" != "${DEFAULT_ABI}" ] ; then
+			# Do not build useless stuff.
+			for i in man doc examples regtest programs ; do
+				sed -i -e "s/ ${i}//" "${BUILD_DIR}/Makefile" || die
+			done
+		fi
+	}
+
+	multilib_parallel_foreach_abi my_configure
+}
+
+src_install() {
+	# note: --htmldir support fixed upstream already,
+	# next version should pass --htmldir to configure instead
+	autotools-multilib_src_install \
+		htmldocdir="${EPREFIX}/usr/share/doc/${PF}/html"
+}