games-strategy/widelands: Bump to version 0.20

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Lars Wendler <[email protected]>

games-strategy/widelands/Manifest

@@ -1,2 +1,3 @@
 DIST widelands-build18-src.tar.bz2 183443325 BLAKE2B 100555b7a800cac1094a768edd40e6b44d6bd0d36386c6f057e0cd81f9b03404b249f259c85d3fae655d7343bb50c41a70f228651530c13092e50190fdd2f9b8 SHA512 9b01c0a7e197360ddd7e21292fc8ba5d1102e24f3a9ec35cfbbf67413a0e9d69abeccd2bc3f6aad05b42cabff32112466803738b41f61562d843779e0c974e72
 DIST widelands-build20-rc1.tar.bz2 232490916 BLAKE2B 7dd13c325fa0dc891a5ab3cc643ae86025c5e853909d172b39d9d1cd2a41132d099f3d03349322b03dc52353f1465391ec006a83e70eb6554be133199efd96b8 SHA512 2d713db8e4a0774e8a6615b6f0dbec4f29870d69fa9bf48db8694316f7320b58ee5afa5a7796e0886471c9c787954c21f478b1364f52ce01a23212a7512465a6
+DIST widelands-build20.tar.bz2 232364340 BLAKE2B 1d8e2cd28d2ac3e2425c91a9872a3f158d7063a2c6c669d95df347561ef35dfca479fd81252d61008a3282c99a2ce70c4d904622272dd86477a731fc711306b1 SHA512 25280db6a57adeb37d13db35ce9eb41a5478534b04772240f6228c180f5a41a55fc414dab66e724945442985cbbba7a8a59a582291aca176e0bd8ae6c08760e5

games-strategy/widelands/widelands-0.20.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop cmake-utils
+
+MY_PV="build$(ver_cut 2-)"
+MY_P="${PN}-${MY_PV/_/-}"
+
+DESCRIPTION="A game similar to Settlers 2"
+HOMEPAGE="http://www.widelands.org/"
+SRC_URI="https://launchpad.net/widelands/build$(ver_cut 2)/${MY_PV/_/-}/+download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-lang/lua:0
+	dev-libs/icu:=
+	>=dev-libs/boost-1.48:=
+	media-libs/glew:0=
+	media-libs/libpng:0=
+	media-libs/libsdl2[video]
+	media-libs/sdl2-gfx
+	media-libs/sdl2-image[jpeg,png]
+	media-libs/sdl2-mixer[vorbis]
+	media-libs/sdl2-net
+	media-libs/sdl2-ttf
+	sys-libs/zlib:=[minizip]"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+CMAKE_BUILD_TYPE="Release"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.20_rc1-cxxflags.patch"
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e 's:__ppc__:__PPC__:' src/map_io/s2map.cc || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DOPTION_BUILD_WEBSITE_TOOLS=OFF
+
+		# Upstream's cmake files are totally fscked up...
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}"/usr/share/doc/${PF}
+		# Game is NOT happy being moved from /usr/share/games
+		-DWL_INSTALL_DATADIR="${EPREFIX}"/usr/share/games/${PN}
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# move game binary to correct location
+	dodir /usr/bin
+	mv "${ED}"/usr/share/doc/${PF}/${PN} "${ED}"/usr/bin || die
+
+	newicon data/images/logos/wl-ico-128.png ${PN}.png
+	make_desktop_entry ${PN} ${PN^}
+}