dev-libs/libisoburn: Version bump libisoburn-1.5.2.

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Daniel Pielmeier <[email protected]>

dev-libs/libisoburn/Manifest

@@ -1 +1,2 @@
 DIST libisoburn-1.5.0.tar.gz 1550656 BLAKE2B 447c383b3847b7ca0c4aca73f5317dec03ef79b34debc3ad2149fae4e7216f29c4a0dd918271087b530fb6c476b219430159e1515bec4bcf51c47d5b2ee05d89 SHA512 c74a9e2887244c28c82abe70d2603dbcd49b639c370e5b7fea03aabce59ff2b361345cd6ec88fe8152727e8a416d4759b88d91e2b5aec8a697408e00b7dc9e4d
+DIST libisoburn-1.5.2.tar.gz 1564700 BLAKE2B 5c7a77f427adff46923f9dc8833f40db36f6ac1ee3b0e58d0111a03ee5c7ae5cc60d613f47d4bb64b848feeb24599b424284cffdbe5c1eebcf7b5e3c58b19b53 SHA512 b481aa5ff20bb35ab0ab19f3f4f3ebc4f2baa8366a14a5afe4f262788441679b6501e140e182f4e80045c747f1cf48db40832d8d5cd064e58a02de2882536897

dev-libs/libisoburn/libisoburn-1.5.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Creation/expansion of ISO-9660 filesystems on CD/DVD media supported by libburn"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wikis/home"
+SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="acl debug external-filters external-filters-setuid frontend-optional
+ launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
+
+REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+RDEPEND="
+ >=dev-libs/libburn-1.5.2
+ >=dev-libs/libisofs-1.5.2
+ readline? ( sys-libs/readline:0= )
+ !readline? ( libedit? ( dev-libs/libedit ) )
+ acl? ( virtual/acl )
+ xattr? ( sys-apps/attr )
+ zlib? ( sys-libs/zlib )
+ launch-frontend? ( dev-lang/tcl:0 dev-lang/tk:0 )
+ launch-frontend-setuid? ( dev-lang/tcl:0 dev-lang/tk:0 )
+ frontend-optional? ( dev-tcltk/bwidget )
+"
+DEPEND="
+ ${RDEPEND}
+"
+
+src_configure() {
+ econf \
+ $(use_enable static-libs static) \
+ $(use_enable readline libreadline) \
+ $(usex readline --disable-libedit $(use_enable libedit)) \
+ $(use_enable acl libacl) \
+ $(use_enable xattr) \
+ $(use_enable zlib) \
+ --disable-libjte \
+ $(use_enable external-filters) \
+ $(use_enable external-filters-setuid) \
+ $(use_enable launch-frontend) \
+ $(use_enable launch-frontend-setuid) \
+ --disable-ldconfig-at-install \
+ --enable-pkg-check-modules \
+ $(use_enable debug)
+}
+
+src_install() {
+ default
+
+ dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
+
+ docinto frontend
+ dodoc frontend/README-tcltk
+ docinto xorriso
+ dodoc xorriso/{changelog.txt,README_gnu_xorriso}
+
+ find "${D}" -name '*.la' -delete || die
+}