media-gfx/simple-scan: bump to 3.34.4

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <[email protected]>

media-gfx/simple-scan/Manifest

@@ -1,2 +1,3 @@
 DIST simple-scan-3.32.2.1.tar.xz 790848 BLAKE2B ded17193c29698a4e07e3d82689fbf84babceb36b2dedb09da5e81ed35399084d6db5b448d3bed56af559a6dc9c8708b4cda1730a248a094e005755b7dd49e95 SHA512 c49620c4be4289b18c792e35a01494a56a28b46e4f246a4c58203cf86cd34a1aa8f42738ef8b50ae6e99150630ec60f999b2000a8ee9674abc4f307db4c6c0cb
 DIST simple-scan-3.32.2.tar.xz 790800 BLAKE2B 98e502cbc280285dbe20a0c843d5f8d8b38707e973f2ba6aba2ccef9d739165371f5f30d7d6658853c5a6a280ba2919a98acd02b4757b4e881f96d5a7b53449b SHA512 10322ae72461efe43a4e230443c3aca24aff6f0cab07750c6eab9ebb718889e51d8c77ff722c337f333a8952ac84f69d03ad88eedfd4432ef11f7c7493170e14
+DIST simple-scan-3.34.4.tar.xz 795228 BLAKE2B b6f185bfbc1954ae2573fd1dcfa54f67e26290654c1019bfd34c229235e27cfc1eb40de0e6d5249f97b73c57745e1133fbd6fd1c3f9bdedb795b61068d5ed25d SHA512 b16b653e0a8ce399ecbdb88c4663d7780793518809eb73681c9c6281b9cde784167090c41720b21c184b9fdece28b07ba61fe8a97f10d792cc7326a458741ba4

media-gfx/simple-scan/simple-scan-3.34.4.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.34"
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.22:3
+	>=sys-libs/zlib-1.2.3.1:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev] )
+	webp? ( media-libs/libwebp )
+	>=media-gfx/sane-backends-1.0.20:=
+
+	virtual/jpeg:0=
+"
+# packagekit? ( >=app-admin/packagekit-base-1.1.5 )
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/3.26-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}