net-misc/gnome-remote-desktop: Version bump to 40.1

And remove the package.mask entry.

Signed-off-by: Matt Turner <[email protected]>

net-misc/gnome-remote-desktop/Manifest

@@ -1 +1,2 @@
 DIST gnome-remote-desktop-40.0.tar.xz 59748 BLAKE2B 73c81a8d6a565cbba1475d122c1a16f02a676a572ac29b69bd5a31de5482b985a0bae7c3b8fda8f4ec1895db87ba2b9ca408347166c7e43c9a0456f5b4fdf7b7 SHA512 557d5425a92cc50dfac60d9e5e39fba88bd3a653ece6490aae663913bc1df490b7d864ae0d6e8cc2c305e7c0fa5f77d7b1e63488bc51f38a0f897232b69edc89
+DIST gnome-remote-desktop-40.1.tar.xz 63980 BLAKE2B 6f5ebe7f00e2038f88740a994ee90f55b7f3ce6e4ea8898b7326d2f36dea2d89c721cffd253f92cde388b1273ad8d086242bfadaa86e4b87361844b3a3bca5b7 SHA512 39116afa16256820a69e020b71de5458fc5da8154bc8255d2157ff56fc679c39f4608f790d74eb4a0cb10cc61bd27d4172cfc547582100cab5b897644a700ee3

net-misc/gnome-remote-desktop/gnome-remote-desktop-40.1.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+inherit gnome.org gnome2-utils meson python-any-r1 systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+rdp +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+ x11-libs/cairo
+ >=dev-libs/glib-2.68:2
+ >=media-video/pipewire-0.3.0:0/0.3
+ app-crypt/libsecret
+ x11-libs/libnotify
+ rdp? (
+ >=net-misc/freerdp-2.3:=[server]
+ >=sys-fs/fuse-3.9.1
+ >=x11-libs/libxkbcommon-1.0.0
+ )
+ vnc? (
+ net-libs/libvncserver
+ )
+"
+RDEPEND="${DEPEND}
+ x11-wm/mutter[screencast]
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ virtual/pkgconfig
+"
+
+src_prepare() {
+ default
+ sed -i -e '/systemd_dep/d' meson.build || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use rdp)
+ $(meson_use vnc)
+ -Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}

profiles/package.mask

@@ -786,10 +786,6 @@ dev-lang/spark
 >=dev-java/eclipse-ecj-4.10
 >=www-servers/tomcat-9
 
-# Mart Raudsepp <[email protected]> (2020-02-16)
-# Fails to automatically launch pipewire for me. Help welcome figuring it out.
-net-misc/gnome-remote-desktop
-
 # Stefan Strogin <[email protected]> (2020-02-12)
 # Mask for testing revdeps.
 >=dev-games/mygui-3.4.0