forked from gentoo/gentoo
-
Notifications
You must be signed in to change notification settings - Fork 0
Commit
This commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
gnome-base/gnome-settings-daemon: Version bump to 40.0.1
Signed-off-by: Matt Turner <[email protected]>
- Loading branch information
Showing
2 changed files
with
148 additions
and
0 deletions.
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -1,2 +1,3 @@ | ||
DIST gnome-settings-daemon-3.38.1.tar.xz 1437096 BLAKE2B dddc4672585c23f1d0f1824303b503ec30d6fc4a2a88b9633e0256d34ca2badd067fa54a404de032f8b2e8dd5b7bfa3915464bc826d8bbea5d57431b7a2ac7fe SHA512 b32c0897d1a5680747bf68e9009ea44cf1a05ef807b772ca6514a278002754d520def7bced929b9004d3aec82a6e82b52637bd2eadd3f6cd54f3d0ac5c8e8cbd | ||
DIST gnome-settings-daemon-40.0.1.tar.xz 1443100 BLAKE2B 2615165e4b33b3ae4f9ceac73fdd298ad5288b5de03424ade70a0dfd64b7349ae759138c0c930ba4c78ff70ed52389b2f0a996333234755f793dc114870d2460 SHA512 d5b7235e097baded66cbbc2c4f05effcac722daa09413f495368555ad97830746415c4c8f1ecfe54dac262f3b75ab1a83863dc4b736b9854dcf86c94c14edd79 | ||
DIST gnome-settings-daemon-40.0.tar.xz 1442648 BLAKE2B 9f4c3923f7cc80ac469719b2a297f4bfc5fb2bf0b5f349d8882481d96a90850f9a062a36447c7bfbff789366efbbd57d77863f63934aadba00918c94c00e8d98 SHA512 59429f8bc01bd84bb50bc297f80ad65e48fef3f0c965ae41571a528b7829e5a3a197e2ded06e1286629a411e5683dfd154267ee99c0dcabbf2d21f389e1f276e |
147 changes: 147 additions & 0 deletions
147
gnome-base/gnome-settings-daemon/gnome-settings-daemon-40.0.1.ebuild
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,147 @@ | ||
# Copyright 1999-2021 Gentoo Authors | ||
# Distributed under the terms of the GNU General Public License v2 | ||
|
||
EAPI=7 | ||
PYTHON_COMPAT=( python3_{7..9} ) | ||
|
||
inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg | ||
|
||
DESCRIPTION="Gnome Settings Daemon" | ||
HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon" | ||
|
||
LICENSE="GPL-2+ LGPL-2+" | ||
SLOT="0" | ||
IUSE="+colord +cups debug elogind input_devices_wacom modemmanager networkmanager smartcard systemd test +udev wayland" | ||
RESTRICT="!test? ( test )" | ||
REQUIRED_USE=" | ||
^^ ( elogind systemd ) | ||
input_devices_wacom? ( udev ) | ||
wayland? ( udev ) | ||
" | ||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris" | ||
|
||
DEPEND=" | ||
>=sci-geosciences/geocode-glib-3.10 | ||
>=dev-libs/glib-2.56:2 | ||
>=gnome-base/gnome-desktop-3.37.1:3= | ||
>=gnome-base/gsettings-desktop-schemas-40 | ||
>=x11-libs/gtk+-3.15.3:3[X,wayland?] | ||
>=dev-libs/libgweather-40:2= | ||
colord? ( | ||
>=x11-misc/colord-1.4.5:= | ||
>=media-libs/lcms-2.2:2 | ||
) | ||
media-libs/libcanberra[gtk3] | ||
>=app-misc/geoclue-2.3.1:2.0 | ||
>=x11-libs/libnotify-0.7.3 | ||
>=media-sound/pulseaudio-2[glib] | ||
>=sys-auth/polkit-0.114 | ||
>=sys-power/upower-0.99.8:= | ||
x11-libs/libX11 | ||
udev? ( dev-libs/libgudev:= ) | ||
wayland? ( dev-libs/wayland ) | ||
input_devices_wacom? ( | ||
>=dev-libs/libwacom-0.7 | ||
>=x11-libs/pango-1.20.0 | ||
x11-libs/gdk-pixbuf:2 | ||
) | ||
smartcard? ( >=dev-libs/nss-3.11.2 ) | ||
cups? ( >=net-print/cups-1.4[dbus] ) | ||
modemmanager? ( | ||
>=app-crypt/gcr-3.7.5:= | ||
>=net-misc/modemmanager-1.0:= | ||
) | ||
networkmanager? ( >=net-misc/networkmanager-1.0 ) | ||
media-libs/alsa-lib | ||
x11-libs/libXi | ||
x11-libs/libXext | ||
media-libs/fontconfig | ||
systemd? ( | ||
>=sys-apps/systemd-243 | ||
sys-apps/dbus[user-session] | ||
) | ||
" | ||
# logind needed for power and session management, bug #464944 | ||
# gnome-session-3.33.90/gdm-3.33.90/gnome-shell-extensions-3.34.1/gnome-flashback-3.33.1 adapt to Clipboard and Mouse component removals (moved to mutter) | ||
RDEPEND="${DEPEND} | ||
gnome-base/dconf | ||
elogind? ( sys-auth/elogind ) | ||
!<gnome-base/gnome-session-3.33.90 | ||
!<gnome-base/gdm-3.33.90 | ||
!<gnome-extra/gnome-shell-extensions-3.34.1 | ||
!<gnome-base/gnome-flashback-3.33.1 | ||
" | ||
# rfkill requires linux/rfkill.h (and USE=udev), thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead | ||
BDEPEND=" | ||
sys-kernel/linux-headers | ||
dev-util/glib-utils | ||
dev-util/gdbus-codegen | ||
x11-base/xorg-proto | ||
${PYTHON_DEPS} | ||
test? ( | ||
$(python_gen_any_dep ' | ||
dev-python/pygobject:3[${PYTHON_USEDEP}] | ||
dev-python/dbusmock[${PYTHON_USEDEP}] | ||
') | ||
gnome-base/gnome-session | ||
) | ||
>=sys-devel/gettext-0.19.8 | ||
virtual/pkgconfig | ||
" | ||
|
||
PATCHES=( | ||
"${FILESDIR}"/${PN}-3.38.1-build-Make-colord-and-wacom-optional-and-controllabl.patch | ||
"${FILESDIR}"/${PN}-3.38.1-build-Allow-NM-optional-on-Linux.patch | ||
"${FILESDIR}"/${PN}-3.38.1-Allow-udev-optional-on-Linux.patch | ||
) | ||
|
||
python_check_deps() { | ||
if use test; then | ||
has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" && | ||
has_version "dev-python/dbusmock[${PYTHON_USEDEP}]" | ||
fi | ||
} | ||
|
||
pkg_setup() { | ||
python-any-r1_pkg_setup | ||
} | ||
|
||
src_configure() { | ||
local emesonargs=( | ||
#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss? | ||
-Dudev_dir="$(get_udevdir)" | ||
$(meson_use systemd) | ||
-Dalsa=true | ||
$(meson_use udev gudev) | ||
$(meson_use colord) | ||
$(meson_use cups) | ||
$(meson_use networkmanager network_manager) | ||
$(meson_use udev rfkill) | ||
$(meson_use smartcard) | ||
$(meson_use input_devices_wacom wacom) | ||
$(meson_use wayland) | ||
$(meson_use modemmanager wwan) | ||
) | ||
meson_src_configure | ||
} | ||
|
||
src_install() { | ||
meson_src_install | ||
# Don't auto-suspend by default on AC power | ||
insinto /usr/share/glib-2.0/schemas | ||
doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override | ||
} | ||
|
||
src_test() { | ||
virtx meson_src_test | ||
} | ||
|
||
pkg_postinst() { | ||
xdg_pkg_postinst | ||
gnome2_schemas_update | ||
} | ||
|
||
pkg_postrm() { | ||
xdg_pkg_postrm | ||
gnome2_schemas_update | ||
} |