games-util/lutris: version 0.5.0.1, add missing deps, xdg

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Marty E. Plummer <[email protected]>
Closes: gentoo#10749
Signed-off-by: Lars Wendler <[email protected]>

games-util/lutris/Manifest

@@ -1 +1,2 @@
 DIST lutris-0.4.23.tar.gz 1831736 BLAKE2B 9da20d5545e9d2474bed436443fed325beb3ed2e3e945cb27e25fbce88ac7aeb9547a0a1bcd74349e5c7bda0dd6be50949b5abaa1fc091a21217b330c6fe655f SHA512 a0860920e01568888db5ac9a52c0d33a5108af33906ea411d4621dec4b059c399b17ca35c245bf9bfb506c6b242d32d917d3ade6898f619e00f9361117632fb3
+DIST lutris_0.5.0.1.tar.xz 1687904 BLAKE2B 646182416201dd4e2fc025b600e569d87821ff98f2fc37ca6029479b7b097466e47135694303f8fc242c4d2632d0b4ecf471919181cd45b095bbff6ba8d973d4 SHA512 a9bf51f388859873de0af43b800692327b098c83966b9e32bbca3ccc0397e1ce5018e751b8f9fef5e83d9de4d1b014e330ffe7d8ab253af7dd2379151297f1bb

games-util/lutris/lutris-0.5.0.1.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+PYTHON_REQ_USE="sqlite,threads(+)"
+
+inherit distutils-r1 virtualx xdg
+
+DESCRIPTION="An open source gaming platform for GNU/Linux"
+HOMEPAGE="https://lutris.net/"
+
+if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI="https://github.com/lutris/lutris.git"
+ inherit git-r3
+else
+ SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+BDEPEND="
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+ app-arch/cabextract
+ app-arch/p7zip
+ app-arch/unrar
+ app-arch/unzip
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-evdev[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ gnome-base/gnome-desktop[introspection]
+ media-sound/fluid-soundfont
+ net-libs/libsoup
+ net-libs/webkit-gtk:4[introspection]
+ x11-apps/xgamma
+ x11-apps/xrandr
+ x11-libs/gtk+:3[introspection]
+"
+
+S="${WORKDIR}/${PN}"
+
+python_install_all() {
+ local DOCS=( AUTHORS README.rst docs/installers.rst )
+ distutils-r1_python_install_all
+}
+
+python_test() {
+ virtx nosetests -v || die
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ # Quote README.rst
+ elog "Lutris installations are fully automated through scripts, which can"
+ elog "be written in either JSON or YAML. The scripting syntax is described"
+ elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+ elog "available online at lutris.net."
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+}

games-util/lutris/lutris-9999.ebuild

@@ -1,68 +1,73 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-PYTHON_COMPAT=( python3_{4,5,6} )
-PYTHON_REQ_USE="sqlite,threads"
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+PYTHON_REQ_USE="sqlite,threads(+)"
 
-inherit distutils-r1 gnome2-utils python-r1
+inherit distutils-r1 virtualx xdg
 
-DESCRIPTION="Lutris is an open source gaming platform for GNU/Linux."
+DESCRIPTION="An open source gaming platform for GNU/Linux"
 HOMEPAGE="https://lutris.net/"
 
-if [[ "${PV}" == "9999" ]] ; then
- EGIT_REPO_URI="https://github.com/lutris/${PN}.git"
+if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI="https://github.com/lutris/lutris.git"
  inherit git-r3
 else
- SRC_URI="https://github.com/lutris/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+ SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
  KEYWORDS="~amd64 ~x86"
 fi
 
 LICENSE="GPL-3"
 SLOT="0"
 
+BDEPEND="
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
 RDEPEND="
- dev-python/dbus-python[${PYTHON_USEDEP}]
+ app-arch/cabextract
+ app-arch/p7zip
+ app-arch/unrar
+ app-arch/unzip
+ dev-python/pillow[${PYTHON_USEDEP}]
  dev-python/pygobject:3[${PYTHON_USEDEP}]
  dev-python/python-evdev[${PYTHON_USEDEP}]
  dev-python/pyyaml[${PYTHON_USEDEP}]
+ gnome-base/gnome-desktop[introspection]
+ media-sound/fluid-soundfont
  net-libs/libsoup
+ net-libs/webkit-gtk:4[introspection]
+ x11-apps/xgamma
  x11-apps/xrandr
- x11-apps/xgamma"
+ x11-libs/gtk+:3[introspection]
+"
 
-python_install() {
- distutils-r1_python_install
-}
-
-src_prepare() {
- distutils-r1_src_prepare
-}
+S="${WORKDIR}/${PN}"
 
-src_compile() {
- distutils-r1_src_compile
+python_install_all() {
+ local DOCS=( AUTHORS README.rst docs/installers.rst )
+ distutils-r1_python_install_all
 }
 
-src_install() {
- # README.rst contains list of optional deps
- DOCS=( AUTHORS README.rst INSTALL.rst )
- distutils-r1_src_install
+python_test() {
+ virtx nosetests -v || die
 }
 
 pkg_preinst() {
- gnome2_icon_savelist
- gnome2_schemas_savelist
+ xdg_pkg_preinst
 }
 
 pkg_postinst() {
- gnome2_icon_cache_update
- gnome2_schemas_update
+ xdg_pkg_postinst
 
- elog "For a list of optional dependencies (runners) see:"
- elog "/usr/share/doc/${PF}/README.rst.bz2"
+ # Quote README.rst
+ elog "Lutris installations are fully automated through scripts, which can"
+ elog "be written in either JSON or YAML. The scripting syntax is described"
+ elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+ elog "available online at lutris.net."
 }
 
 pkg_postrm() {
- gnome2_icon_cache_update
- gnome2_schemas_update
+ xdg_pkg_postrm
 }