app-emulation/fs-uae-launcher: Version bump to 3.0.0

Package-Manager: Portage-2.3.79, Repoman-2.3.17
Signed-off-by: James Le Cuirot <[email protected]>

app-emulation/fs-uae-launcher/Manifest

@@ -1 +1,2 @@
 DIST fs-uae-launcher-3.0.0.tar.gz 9631352 BLAKE2B dc2f940cbde1fe9d2386e512bf5c0ca9a4ea19332826095cc5ba95e90c7f6cfaf0cd5dbaa692c192ac7d74a3ddf245062a0faeeccc9d8a135e544d304119e239 SHA512 76f9c48d2a46ece38aebb318a6d684ff40e85fef76bcc6ac57c7f397c828dae45541ba458a7792f102a8afc69a4183b9932b637318716a8b40ff3dbd3b37cad7
+DIST fs-uae-launcher-3.0.2.tar.gz 9633002 BLAKE2B 81e5a9cbdb4f094735fdbffa291c86bea74e3306ea1bc8365ba215daf970665ab45515c82dd180bfc965f5a2ff83c29a9cd8b21b343e6e6c7ebb4d95dbafd8d0 SHA512 6e9d5588b4cee79b7d5468b7d5e3d6c82e54957fcb0b05d3e9d1da8710336f0af82821fea37ee4cf4e0dc12ead6096183fe488afe860ce11573fd828718ba3d3

app-emulation/fs-uae-launcher/fs-uae-launcher-3.0.2.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="PyQt5-based launcher for FS-UAE"
+HOMEPAGE="https://fs-uae.net/"
+SRC_URI="https://fs-uae.net/stable/${PV}/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="lha"
+
+RDEPEND="
+	app-emulation/fs-uae
+	dev-python/PyQt5[${PYTHON_USEDEP},declarative,gui,network,opengl,widgets]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	lha? ( dev-python/python-lhafile[${PYTHON_USEDEP}] )
+"
+
+DEPEND="
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.0-ROMs.patch
+	"${FILESDIR}"/${PN}-2.8.3-QApplication.patch
+)
+
+src_prepare() {
+	default
+
+	# Unbundle OpenGL library. Keep oyoyo IRC library because upstream
+	# is long dead and it's not worth packaging separately.
+	rm -r OpenGL || die
+	sed -i -r "/OpenGL/d" setup.py || die
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	local dir=${EPREFIX}/usr/share/${PN}
+	distutils-r1_python_install --install-lib="${dir}" --install-scripts="${dir}"
+	dosym ../share/${PN}/${PN} /usr/bin/${PN}
+
+	emake install-data DESTDIR="${D}" prefix="${EPREFIX}"/usr
+	mv "${ED}"/usr/share/doc/{${PN},${PF}} || die
+}
+
+pkg_postinst() {
+	elog "Some important information:"
+	elog
+	ewarn " - Do not use QtCurve, it will crash PyQt5!"
+	elog
+	elog " - By default, FS-UAE creates its directories under Documents/FS-UAE."
+	elog "   If your Documents directory is not configured according to the XDG"
+	elog "   user diretory spec, ~/FS-UAE will be used as a fallback."
+	elog
+	elog " - You can override this by putting the path to the desired base"
+	elog "   directory in a special config file. The config file will be read"
+	elog "   from ~/.config/fs-uae/base-dir by both FS-UAE and FS-UAE Launcher"
+	elog "   if it exists."
+	elog
+	elog "   Alternatively, you can start FS-UAE and/or FS-UAE Launcher with"
+	elog "   --base-dir=/path/to/desired/dir"
+}
+
+pkg_postinst() { xdg_icon_cache_update; }
+pkg_postrm() { xdg_icon_cache_update; }