gnome-extra/cinnamon-settings-daemon: 5.0.0 version bump

Bug: https://bugs.gentoo.org/792933
Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Matthew S. Turnbull <[email protected]>
Signed-off-by: Sam James <[email protected]>

gnome-extra/cinnamon-settings-daemon/Manifest

@@ -1,2 +1,3 @@
 DIST cinnamon-settings-daemon-4.6.4.tar.gz 668339 BLAKE2B 80e14d29a74004c1778e90d39c6ca892d3eee778134e43b8ea77cfec8cbad4f5ac21609cfbb9cdaab0b4d35b42e897223a5b9cdfd43de49d8112b8bc6fc45914 SHA512 77ddb637fd93fdfd59fb27c5a10082259fd99b4753ff36b3473db12f2fe0d19ee89d44c9e72f1ce9eab3f228c5fef418ce774dd78746d77b959ad9d8f93c1208
 DIST cinnamon-settings-daemon-4.8.5.tar.gz 662123 BLAKE2B b3ddd72e55c10c2cacc6dd29145e381395bd2ef68db7082a0770bb3eb647964041ed023d4a8357f2adcf5e8c9f8f713bac837809ed5926cc0434c2dc3e5c90ad SHA512 4a1d128b3f6faf3e2c13420d3569d4fd8cfaa1798ba5cf83fcb692662b9888d22f9f4bfb6fe18af59d0632583a2730a07e3ab48cca12c357b2d318d205fd7d0a
+DIST cinnamon-settings-daemon-5.0.0.tar.gz 662485 BLAKE2B 33c7cf208f66f480ab3d70e4e7627e65f059ae13a3f24142f6cd0743752f9d636066c2ed8a805c649726280887b882bc0bc53e4c590888937bb977183a43e4ef SHA512 0e2ef144717ca41d946d6467931fb45eabf3468025e6bc4cf25f9b11f2d94dae07f7649874d801b312d94905d30d4e74202bf8f01af53689179039865ea54052

gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.0.0.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson gnome2-utils python-any-r1 xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-settings-daemon"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+
+RDEPEND="
+ >=dev-libs/glib-2.40.0:2
+ dev-libs/libgudev:=
+ >=gnome-base/libgnomekbd-3.6
+ >=gnome-extra/cinnamon-desktop-5.0:0=
+ media-libs/fontconfig
+ >=media-libs/lcms-2.2:2
+ media-libs/libcanberra:0=[gtk3,pulseaudio]
+ >=media-sound/pulseaudio-0.9.16[glib]
+ >=sys-apps/dbus-1.1.2
+ dev-libs/dbus-glib
+ >=sys-auth/polkit-0.97
+ x11-libs/gdk-pixbuf:2
+ >=x11-libs/gtk+-3.14.0:3
+ >=x11-libs/libnotify-0.7.3:0=
+ x11-libs/libX11
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXi
+ >=x11-libs/libxklavier-5.0
+ >=sys-power/upower-0.9.11
+
+ colord? ( >=x11-misc/colord-0.1.27:= )
+ cups? (
+ >=net-print/cups-1.4[dbus]
+ app-admin/system-config-printer
+ net-print/cups-pk-helper )
+ input_devices_wacom? (
+ >=dev-libs/libwacom-0.7
+ >=gnome-base/librsvg-2.36.2
+ x11-drivers/xf86-input-wacom
+ x11-libs/libXtst )
+ smartcard? ( >=dev-libs/nss-3.11.2 )
+ systemd? ( sys-apps/systemd:0= )
+ !systemd? ( sys-auth/elogind:0= )
+"
+DEPEND="
+ ${RDEPEND}
+ dev-libs/libxml2:2
+ x11-base/xorg-proto
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ dev-util/glib-utils
+ dev-util/gdbus-codegen
+ >=dev-util/intltool-0.37.1
+ virtual/pkgconfig
+"
+
+src_prepare() {
+ default
+ python_fix_shebang install-scripts
+}
+
+src_configure() {
+ # gudev not optional on Linux platforms
+ local emesonargs=(
+ -Duse_gudev=enabled
+ -Duse_polkit=enabled
+ -Duse_logind=enabled
+ $(meson_feature colord use_color)
+ $(meson_feature cups use_cups)
+ $(meson_feature smartcard use_smartcard)
+ $(meson_feature input_devices_wacom use_wacom)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}