media-video/jubler: version bump.

Gentoo-Bug: https://bugs.gentoo.org/540302

Package-Manager: Portage-2.3.5, Repoman-2.3.1

media-video/jubler/Manifest

@@ -1 +1,2 @@
 DIST Jubler-source-4.6.1.tar.bz2 1971701 SHA256 1aeed14cc500165470b29884585432e9d14940c314bafa0f6318789005dd18f1 SHA512 629aef58f98d2d8569a58a4c68c9bf440cd4693ca8847a0b8ad9e84458cd88de44542b5fc84e25033c1e22b26a4d675e070c5a58203a6bbe671072e5cdc2680a WHIRLPOOL bf3e95a5515e3895a6773433681f5abfebc159f30b8a91acf51aa6ea961247db8686ab3d92112725b5443b5f1ffb16a5cc4c46036e7b3fa6a5a562e6c7ae211d
+DIST jubler-5.1.tar.bz2 1815531 SHA256 bee88e6e6210ee525749bfb6469261a0ff129ed0233286010503b69b8390c8e6 SHA512 e2a0da737362a3c8dc12966aec1e9939291237fc714a586186b72daa16abf967c8fea8dac04fb191cb803aa11db20cf6d67468d2383f17f5c6114a643860acef WHIRLPOOL 8a5c5ed8f3225ad4984f9755acefe2171460639896baaace0bcbdcd2a9ffcf553b87f3aab8d5b4e8370bee0b97f524050a0fd34bfa1a1592b96a44d8ff7b0f56

media-video/jubler/jubler-5.1.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit fdo-mime java-pkg-2 java-ant-2
+
+MY_PN="${PN^}"
+
+DESCRIPTION="Java subtitle editor"
+HOMEPAGE="http://www.jubler.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-source-${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="mplayer spell nls"
+
+RDEPEND="
+ mplayer? ( media-video/mplayer[libass] )
+ spell? ( app-text/aspell )
+ >=virtual/jre-1.6"
+
+DEPEND="
+ >=virtual/jdk-1.6"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+ default
+
+ local REMOVE_PLUGINS=() _plugin
+ use mplayer || REMOVE_PLUGINS+=( mplayer )
+ use spell || REMOVE_PLUGINS+=( aspell zemberek )
+ for _plugin in "${REMOVE_PLUGINS[@]}"; do
+ rm -rv "plugins/${_plugin}" || die
+ done
+}
+
+src_compile() {
+ local JUBLER_TARGETS=()
+ use nls || JUBLER_TARGETS+=( core help )
+ eant -f "${S}/build.xml" "${JUBLER_TARGETS[@]}"
+}
+
+src_install() {
+ DESTDIR="${D}" eant linuxdesktopintegration
+ rm -rv "${D}/usr/share/menu" || die
+
+ doicon "resources/installers/linux/${PN}.png"
+ domenu "resources/installers/linux/${PN}.desktop"
+
+ java-pkg_dojar dist/Jubler.jar
+ java-pkg_dolauncher "${PN}" --main Jubler
+
+ if use nls; then
+ insinto "/usr/share/${PN}/lib/i18n/"
+ doins dist/i18n/*.jar
+ fi
+
+ insinto "/usr/share/${PN}/lib/themes"
+ doins dist/themes/coretheme.jar
+ insinto "/usr/share/${PN}/lib/lib"
+ doins dist/lib/*.jar
+
+ insinto "/usr/share/${PN}/help"
+ doins resources/help/*
+
+ doman "resources/installers/linux/${PN}.1"
+ einstalldocs
+}
+
+pkg_postinst() {
+ fdo-mime_desktop_database_update
+ fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+ fdo-mime_desktop_database_update
+ fdo-mime_mime_database_update
+}