dev-vcs/tortoisehg: 5.8.1 version bump

Signed-off-by: Sergey Torokhov <[email protected]>
Signed-off-by: Joonas Niilola <[email protected]>

dev-vcs/tortoisehg/Manifest

@@ -1 +1,2 @@
 DIST tortoisehg-5.8.tar.gz 8636455 BLAKE2B 1f4171ca4eb465aabacaf53b97785c5f05fc501a11329af008695f706d8d2cb9c5eee5e64bb5a60fdf7234f33ed6a937dfacce49cb36ac9e9b8505be271b4f35 SHA512 b9fe80a98cfafe0dbc90be5fe6f83b466fe596b4ec135d0eacc5618e39c0249a3a352bed640a7cecb99d53eaf60908d60d7748009492cbd8202fc191ef428278
+DIST tortoisehg-5.8.1.tar.gz 8636858 BLAKE2B 66473695e1364ff676ab314ce8b5a5e59cbe6ece68795d92278e450f70386a9e047dfd8975e7312bda10c183879d9634767f64a9c916f889f3edcf4847bf2468 SHA512 29903240c5522841e0ddc0f78741d20d589b6b48e82bf38023b87184e987721111a6a9675ccb85a31d9781cf1b8fa3d28801fef5bae187ae467d7da8f1ef982f

dev-vcs/tortoisehg/tortoisehg-5.8.1.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..9} )
+
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit desktop distutils-r1 optfeature xdg-utils
+
+if [[ ${PV} != *9999* ]]; then
+ KEYWORDS="~amd64 ~arm64 ~x86"
+ SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
+ HG_DEPEND=">=dev-vcs/mercurial-5.7[${PYTHON_USEDEP}]
+ <dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]"
+ S="${WORKDIR}/thg-${PV}"
+else
+ inherit mercurial
+ EHG_REPO_URI="https://foss.heptapod.net/mercurial/${PN}/thg"
+ EHG_REVISION="stable"
+ HG_DEPEND=">=dev-vcs/mercurial-5.7[${PYTHON_USEDEP}]"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ ${HG_DEPEND}
+ dev-python/iniparse[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+ >=dev-python/qscintilla-python-2.9.4[qt5(+),${PYTHON_USEDEP}]
+"
+DEPEND="
+ ${RDEPEND}
+ test? (
+ dev-python/mock
+ dev-python/pytest
+ )
+"
+
+distutils_enable_sphinx doc/source
+
+python_prepare_all() {
+ # Remove file that collides with >=mercurial-4.0 (bug #599266).
+ rm "${S}"/hgext3rd/__init__.py || die "can't remove /hgext3rd/__init__.py"
+
+ sed -i -e 's:share/doc/tortoisehg:share/doc/'"${PF}"':' setup.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ ${EPYTHON} tests/run-tests.py -m 'not largefiles' --doctest-modules tests || die
+ ${EPYTHON} tests/run-tests.py -m largefiles tests || die
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+ newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+ domenu contrib/thg.desktop
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ elog "When startup of ${PN} fails with an API version mismatch error"
+ elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+ elog "dev-python/qscintilla-python."
+
+ optfeature "the core git extension support" dev-python/pygit2
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}