Skip to content

Commit

Permalink
gui-wm/sway: bump to 1.5.1
Browse files Browse the repository at this point in the history
Signed-off-by: Aaron Bauman <[email protected]>
  • Loading branch information
FuzzyGophers committed Nov 10, 2020
1 parent 7437d18 commit f122a96
Show file tree
Hide file tree
Showing 2 changed files with 119 additions and 0 deletions.
1 change: 1 addition & 0 deletions gui-wm/sway/Manifest
Original file line number Diff line number Diff line change
@@ -1 +1,2 @@
DIST sway-1.5.1.tar.gz 5536721 BLAKE2B 4dcb6ca380ef8451ab9219a584598928a79e999bc0b1de0599cb7867c8fd94d54c55a2be9585635b4fd230fd83852141d6fd41ef35dbc4a8fef1bcc2828b3be4 SHA512 3b937249db2875100bc22e99f955a3300d3294a296fb37006fa1468a3986bf4fa8e5197279e3587bd8dc29f31adff8fbdc9ddc840e7be982b73331a05cd06ba5
DIST sway-1.5.tar.gz 5535966 BLAKE2B e863e97ee897dcd1652d363a09b712932de55da08c88b4858f0aadc29b2cb19d2bda1e5e1184f4e4be6fa54a0136463556f9072f32e2b952d4f12ffd0ee9baf9 SHA512 702e44f8923a4ca05d831dd7ed76165654f113a8b2754d332c509ee844528f47c52b7f21deca78d4a79dad465cbcd0934574fff4ad9bb7a45aec3124dea5bca4
118 changes: 118 additions & 0 deletions gui-wm/sway/sway-1.5.1.ebuild
Original file line number Diff line number Diff line change
@@ -0,0 +1,118 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit eutils meson

DESCRIPTION="i3-compatible Wayland window manager"
HOMEPAGE="https://swaywm.org"

if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
else
MY_PV=${PV/_rc/-rc}
SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
S="${WORKDIR}/${PN}-${MY_PV}"
fi

LICENSE="MIT"
SLOT="0"
IUSE="elogind fish-completion +man +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag systemd tray wallpapers X zsh-completion"
REQUIRED_USE="?? ( elogind systemd )
tray? ( || ( elogind systemd ) )"

DEPEND="
>=dev-libs/json-c-0.13:0=
>=dev-libs/libinput-1.6.0:0=
dev-libs/libpcre
dev-libs/wayland
x11-libs/cairo
x11-libs/libxkbcommon
x11-libs/pango
x11-libs/pixman
media-libs/mesa[gles2,libglvnd(+)]
elogind? ( >=sys-auth/elogind-239 )
swaybar? ( x11-libs/gdk-pixbuf:2 )
swaybg? ( gui-apps/swaybg )
swayidle? ( gui-apps/swayidle )
swaylock? ( gui-apps/swaylock )
systemd? ( >=sys-apps/systemd-239 )
wallpapers? ( x11-libs/gdk-pixbuf:2[jpeg] )
X? ( x11-libs/libxcb:0= )
"
if [[ ${PV} == 9999 ]]; then
DEPEND+="~gui-libs/wlroots-9999:=[elogind=,systemd=,X=]"
else
DEPEND+="
>=gui-libs/wlroots-0.12.0:=[elogind=,systemd=,X=]
<gui-libs/wlroots-0.13.0:=[elogind=,systemd=,X=]
"
fi
RDEPEND="
x11-misc/xkeyboard-config
${DEPEND}
"
BDEPEND="
>=dev-libs/wayland-protocols-1.14
>=dev-util/meson-0.53.0
virtual/pkgconfig
"
if [[ ${PV} == 9999 ]]; then
BDEPEND+="man? ( ~app-text/scdoc-9999 )"
else
BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
fi

src_prepare() {
default

use swaybar || sed -e "s/subdir('swaybar')//g" -e "/sway-bar.[0-9].scd/d" \
-e "/completions\/[a-z]\+\/_\?swaybar/d" -i meson.build || die
use swaymsg || sed -e "s/subdir('swaymsg')//g" -e "/swaymsg.[0-9].scd/d" \
-e "/completions\/[a-z]\+\/_\?swaymsg/d" -i meson.build || die
use swaynag || sed -e "s/subdir('swaynag')//g" -e "/swaynag.[0-9].scd/d" \
-e "/completions\/[a-z]\+\/_\?swaynag/d" -i meson.build || die
}

src_configure() {
local emesonargs=(
-Dman-pages=$(usex man enabled disabled)
-Dtray=$(usex tray enabled disabled)
-Dxwayland=$(usex X enabled disabled)
$(meson_use wallpapers default-wallpaper)
$(meson_use fish-completion fish-completions)
$(meson_use zsh-completion zsh-completions)
"-Dbash-completions=true"
"-Dwerror=false"
)

if use swaybar; then
emesonargs+=("-Dgdk-pixbuf=enabled")
else
emesonargs+=("-Dgdk-pixbuf=disabled")
fi

meson_src_configure
}

pkg_preinst() {
if ! use systemd && ! use elogind; then
fowners root:0 /usr/bin/sway
fperms 4511 /usr/bin/sway
fi
}

pkg_postinst() {
if ! use systemd && ! use elogind; then
elog ""
elog "If you use ConsoleKit2, remember to launch sway using:"
elog "exec ck-launch-session sway"
elog ""
elog "If your system does not set the XDG_RUNTIME_DIR environment"
elog "variable, you must set it manually to run Sway. See wiki"
elog "for details: https://wiki.gentoo.org/wiki/Sway"
fi
}

0 comments on commit f122a96

Please sign in to comment.