media-libs/sdl2-mixer: Bump to version 2.0.4

Signed-off-by: Lars Wendler <[email protected]>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

media-libs/sdl2-mixer/Manifest

@@ -1 +1,2 @@
 DIST SDL2_mixer-2.0.2.tar.gz 9620763 BLAKE2B 9257f7f3dc3453b600075011f1879391c4a4def2c67709a883a8803f752928d3883fbe11371609cd5e690647a33b43bfd38f152aa620f63af12e1b7b72fa0ec4 SHA512 c40b5ac93933df1cc932e7afe796ad6765aafb24077601a23f98ac625a83341079ad903c164eafd022aff6011872e7a7956eebd8e3d3edad1bf5dc7eb9c306b7
+DIST SDL2_mixer-2.0.4.tar.gz 11125077 BLAKE2B ccb55020e360fa000e82807b8c4e2371228291943d2dc7371606834ca0f781d4e82581b5427e9902156bf3072208db4ec07e95a06f206e40ff530f432dd9e491 SHA512 98c56069640668aaececa63748de21fc8f243c7d06386c45c43d0ee472bbb2595ccda644d9886ce5b95c3a3dee3c0a96903cf9a89ddc18d38f041133470699a3

media-libs/sdl2-mixer/sdl2-mixer-2.0.4.ebuild

@@ -0,0 +1,111 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="SDL2_mixer-${PV}"
+inherit multilib-minimal
+
+DESCRIPTION="Simple Direct Media Layer Mixer Library"
+HOMEPAGE="https://www.libsdl.org/projects/SDL_mixer/"
+SRC_URI="https://www.libsdl.org/projects/SDL_mixer/release/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~x86"
+IUSE="flac fluidsynth mad midi mikmod mod modplug mp3 opus playtools static-libs timidity tremor vorbis +wav"
+REQUIRED_USE="
+ midi? ( || ( timidity fluidsynth ) )
+ timidity? ( midi )
+ fluidsynth? ( midi )
+ mad? ( mp3 )
+ mod? ( || ( mikmod modplug ) )
+ mikmod? ( mod )
+ modplug? ( mod )
+ tremor? ( vorbis )
+"
+
+RDEPEND="
+ >=media-libs/libsdl2-2.0.7[${MULTILIB_USEDEP}]
+ flac? ( >=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}] )
+ midi? (
+ fluidsynth? ( >=media-sound/fluidsynth-1.1.6-r1[${MULTILIB_USEDEP}] )
+ timidity? ( media-sound/timidity++ )
+ )
+ mod? (
+ mikmod? ( >=media-libs/libmikmod-3.3.6-r1[${MULTILIB_USEDEP}] )
+ modplug? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
+ )
+ mp3? (
+ mad? ( >=media-libs/libmad-0.15.1b-r8[${MULTILIB_USEDEP}] )
+ !mad? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+ )
+ opus? ( >=media-libs/opusfile-0.2 )
+ vorbis? (
+ tremor? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+ !tremor? (
+ >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
+ >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+ )
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+multilib_src_configure() {
+ local myeconfargs=(
+ $(use_enable static-libs static)
+ --disable-sdltest
+ --enable-music-cmd
+ $(use_enable wav music-wave)
+ $(use_enable mod music-mod)
+ $(use_enable modplug music-mod-modplug)
+ --disable-music-mod-modplug-shared
+ $(use_enable mikmod music-mod-mikmod)
+ --disable-music-mod-mikmod-shared
+ $(use_enable midi music-midi)
+ $(use_enable timidity music-midi-timidity)
+ $(use_enable fluidsynth music-midi-fluidsynth)
+ --disable-music-midi-fluidsynth-shared
+ $(use_enable vorbis music-ogg)
+ $(use_enable tremor music-ogg-tremor)
+ --disable-music-ogg-shared
+ $(use_enable flac music-flac)
+ --disable-music-flac-shared
+ $(use_enable mp3 music-mp3)
+ $(use_enable !mad music-mp3-mpg123)
+ --disable-music-mp3-mpg123-shared
+ $(use_enable mad music-mp3-mad-gpl)
+ $(use_enable opus music-opus)
+ --disable-music-opus-shared
+ LIBMIKMOD_CONFIG=${EPREFIX}/usr/bin/${CHOST}-libmikmod-config
+ )
+ ECONF_SOURCE=${S} econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+ emake DESTDIR="${D}" install
+ if multilib_is_native_abi && use playtools ; then
+ emake DESTDIR="${D}" install-bin
+ fi
+}
+
+multilib_src_install_all() {
+ dodoc {CHANGES,README}.txt
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ # bug 412035
+ # https://bugs.gentoo.org/show_bug.cgi?id=412035
+ if use midi && use fluidsynth; then
+ ewarn "FluidSynth support requires you to set the SDL_SOUNDFONTS"
+ ewarn "environment variable to the location of a SoundFont file"
+ ewarn "unless the game or application happens to do this for you."
+ if use timidity; then
+ ewarn "Failing to do so will result in Timidity being used instead."
+ else
+ ewarn "Failing to do so will result in silence."
+ fi
+ fi
+}