gnome-extra/gnome-shell-extension-dash-to-panel: Bump to v29

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Pacho Ramos <[email protected]>

gnome-extra/gnome-shell-extension-dash-to-panel/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-shell-extension-dash-to-panel-26.tar.gz 21100594 BLAKE2B da90d4f496e10c14c554edb74065c95bf211f6778c097e3b81d863a46d0d3477f281cebac72f334b461f28b998284a861363b27d6c17ef5b1d47947a1f44bf01 SHA512 45bc148d2419db5943d0c2170ea3739a36c5a928c39d070501c5dfbec3910ba08058af1926c42f75d6b3e5918d8c30aef4f38db0af14115c11027520fa582a2f
+DIST gnome-shell-extension-dash-to-panel-29.tar.gz 21107847 BLAKE2B 1a5440208a61ddadd0f0a3f22cfe2d2d675ad2784757aef69eb16c305c5b1a86ecfe1a73e22457d2641f599ab1d8162b24cc573621c33cbd0298a24ef9faf4c1 SHA512 6ed189a5ac5ac00d9ce33701dbde898c81c37ac13da353c9e44cea835ca4b7ab748e42cca4639e9c1f4f6dafe2ba6c5b72ba524eca67eb8365aec354ddfca05c
 DIST tango-gentoo-v1.1.tar.gz 29322 BLAKE2B 83fa2bf37727e60851dd679054fe1b153ebfea58c9a9a40f891f7d68d3b047b02e8effa1d1b4e08d64500a2072ce7200f159c92a352da7124de27e1b05bb6027 SHA512 87d47ddab68361db6d99866c51705dcb3e198f8345a1096859acf2c6cca5099dd23c7fb30d124f52c4933ea38fd45fadffbbe6ecbdfa84f5b60938a4824f9045

gnome-extra/gnome-shell-extension-dash-to-panel/gnome-shell-extension-dash-to-panel-29.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils
+
+MY_PN="${PN/gnome-shell-extension-/}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="An icon taskbar for the Gnome Shell"
+HOMEPAGE="https://github.com/home-sweet-gnome/dash-to-panel"
+SRC_URI="
+	https://github.com/home-sweet-gnome/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	branding? ( https://www.mail-archive.com/[email protected]/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="branding"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-3.18.0
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	# Enable by default custom opacity to get panel slightly transparent
+	# as was done in older Gnome versions
+	"${FILESDIR}"/${PN}-26-opacity.patch
+)
+
+src_prepare() {
+	default
+
+	# Set correct version
+	export VERSION="${PV}"
+
+	# Don't install README and COPYING in unwanted locations
+	sed -i -e 's/COPYING//g' -e 's/README.md//g' Makefile || die
+
+	# Provide fancy Gentoo icon when requested
+	use branding && eapply "${FILESDIR}"/${PN}-26-branding.patch
+}
+
+src_install() {
+	default
+	if use branding; then
+		insinto /usr/share/gnome-shell/extensions/[email protected]/img
+		doins "${WORKDIR}/tango-gentoo-v1.1/scalable/gentoo.svg"
+	fi
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}