dev-vcs/tortoisehg: Bump to version 4.5

Package-Manager: Portage-2.3.24, Repoman-2.3.6

dev-vcs/tortoisehg/Manifest

@@ -1,2 +1,3 @@
 DIST tortoisehg-4.4.1.tar.gz 7923557 BLAKE2B b2574bb87693a3fb824c3c02424b8f5828c1e3673b111ae82ff0692588083eec639a67b200ce6e3def58e5a0e021898c3df62a053fa61d477f92d4226d3a1b69 SHA512 b364e6d16845c03aacaf691e8528e0bd87151026f9f55bcaf61ba67d1eebfc3f9935457e5ca3391e29417682367b9b33803a9870817c22db31f1dd26850e9d53
 DIST tortoisehg-4.4.2.tar.gz 8939270 BLAKE2B 858ef57f6e80244ebb99b43608b1d939896f60d2154e461a128efdb0d5ebffbf1b8d5a9a40596316b0bed8edd74e292b5e562e3119f75177d430c081ba07511c SHA512 6b0335d8022d015846d456d351b168f826afa5223b77ee45f2124fbd1099904cca4e2a3ca6cb7a48324491211a149bd431d29fab6932e8f8240542e13d814381
+DIST tortoisehg-4.5.tar.gz 8941832 BLAKE2B b5dda8acf483400bc7cdcc511ca26bb7edbda94aa7ce03fe2b2e3eadc4e7616a7773e7aa974815d51e06a0a8014186b3cb1817eb751509ee85db8b1a3cd4a5b9 SHA512 258956c1d8f7e3b47f35be1d4587a51bbf79d3b9bd218ab16dbfd36c366570b3b8d32fb9b9af54c3389f69e98185185e7900e6f26fb46d6024c979fb6dfb0f3f

dev-vcs/tortoisehg/tortoisehg-4.5.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-4.4 <dev-vcs/mercurial-4.6"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+	EHG_REVISION="stable"
+	HG_DEPEND="dev-vcs/mercurial"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.9.4:=[qt5(+),${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-1.0.3 )"
+
+# Workaround race condition in build_qt
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	if [[ ${L10N+set} ]]; then
+		cd i18n/tortoisehg || die
+		local x y keep
+		for x in *.po; do
+			keep=false
+			for y in ${L10N}; do
+				if [[ ${y} == ${x%.po}* ]]; then
+					keep=true
+					break
+				fi
+			done
+			${keep} || rm "${x}" || die
+		done
+		cd "${S}" || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	if use doc ; then
+		dohtml -r doc/build/html/
+	fi
+	newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+	domenu contrib/thg.desktop
+
+	# Remove file that collides with >=mercurial-4.0 (bug #599266).
+	rm "${ED%/}"/usr/$(get_libdir)/${EPYTHON}/site-packages/hgext3rd/__init__.py \
+		|| die
+}
+
+pkg_postinst() {
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+	elog "dev-python/qscintilla-python."
+}