dev-cpp/libcmis: Add USE tools

Package-Manager: Portage-2.3.64, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <[email protected]>
johu · Apr 21, 2019 · 0369fd9 · 0369fd9
1 parent 3b1e04f
commit 0369fd9
Show file tree

Hide file tree

Showing 3 changed files with 78 additions and 19 deletions.
diff --git a/dev-cpp/libcmis/libcmis-0.5.2-r1.ebuild b/dev-cpp/libcmis/libcmis-0.5.2-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+inherit autotools flag-o-matic
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://github.com/tdf/libcmis"
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0.5"
+
+IUSE="man static-libs test tools"
+
+BDEPEND="
+	virtual/pkgconfig
+	man? (
+		app-text/docbook2X
+		dev-libs/libxslt
+	)
+	test? (
+		dev-util/cppcheck
+		dev-util/cppunit
+	)
+"
+DEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug 618778
+	append-cxxflags -std=c++14
+
+	local myeconfargs=(
+		--program-suffix=-$(ver_cut 1-2)
+		--disable-werror
+		$(use_with man)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		$(use_enable tools client)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-cpp/libcmis/libcmis-9999.ebuild b/dev-cpp/libcmis/libcmis-9999.ebuild
@@ -1,16 +1,14 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 if [[ ${PV} = 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
 	inherit git-r3
-elif [[ ${PV} = *_pre* ]]; then
-	COMMIT=738528d790b2b1d52d9b72d673842969a852815d
-	SRC_URI="https://github.com/tdf/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
 else
 	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
 fi
 inherit autotools flag-o-matic
 
@@ -20,18 +18,8 @@ HOMEPAGE="https://github.com/tdf/libcmis"
 LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
 SLOT="0.5"
 
-# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="man static-libs test tools"
 
-IUSE="man static-libs test"
-
-RDEPEND="
-	dev-libs/boost:=
-	dev-libs/libxml2
-	net-misc/curl
-"
-DEPEND="${RDEPEND}"
 BDEPEND="
 	virtual/pkgconfig
 	man? (
@@ -43,11 +31,15 @@ BDEPEND="
 		dev-util/cppunit
 	)
 "
+DEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+RDEPEND="${DEPEND}"
 
 RESTRICT="test"
 
-[[ ${PV} = *_pre* ]] && S="${WORKDIR}/${PN}-${COMMIT}"
-
 src_prepare() {
 	default
 	eautoreconf
@@ -63,7 +55,7 @@ src_configure() {
 		$(use_with man)
 		$(use_enable static-libs static)
 		$(use_enable test tests)
-		--enable-client
+		$(use_enable tools client)
 	)
 	econf "${myeconfargs[@]}"
 }

diff --git a/dev-cpp/libcmis/metadata.xml b/dev-cpp/libcmis/metadata.xml
@@ -6,7 +6,8 @@
 		<name>Gentoo Office project</name>
 	</maintainer>
 	<use>
-		<flag name="man">Build and install man pages.</flag>
+		<flag name="man">Build and install man pages</flag>
+		<flag name="tools">Build client tool for testing and viewing features</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">tdf/libcmis</remote-id>