games-util/pyfa: version bump to 2.37.0

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Andreas Zuber <[email protected]>
Signed-off-by: Joonas Niilola <[email protected]>

games-util/pyfa/Manifest

@@ -1,2 +1,3 @@
 DIST pyfa-2.32.0.tar.gz 28170873 BLAKE2B 92839a83067f3699dfcf85a6e479c16a80e18f375f402654dd2b1207497bfba639e717d3ff205cc682a8cbf3cefd37990c7d6dccf46e9dbf23bfd416c58eba81 SHA512 998a1055a5d68cdf61603ecac503db24a8ea344cd388acc7f1f04aafe54b22db059461619c1a1d93b807dc64c779a158b6b2d5066412d6ffc3df0a858de83b0e
 DIST pyfa-2.33.0.tar.gz 28872031 BLAKE2B fe7fad57e43a8efc78f828d0ff81788147fa64ef02a20a71d6fef8ab0130d39b5ebffc18d58a774a61d805b8d0e570cbedb0b8fa536c8c71e61102fb6d093998 SHA512 bfa4e41b387e9f23aeae41a4884a0492316cc6e51841243ef56dc733edab10e6c9609ca7918d4de9fcd052b4da8f8048ce7578d164ad98237b53cb05f7c168d8
+DIST pyfa-2.37.0.tar.gz 29991827 BLAKE2B d2dd51becc037176ef0e4394799d6d35ea5025b4b9aba7a1e2a12d908b1d8d9a436d2e2b2e9d06b3592ea2276b3dfe24c639d02cd77fe25a6ea673d9f048a238 SHA512 e3ccee3ee3b74644f208afdf719bf1e3dc29335041e3cdd19b5742f51e1fbb0fcab2376c26fc789e7992d1f35215c128bf6480860a0eea75eeb69c9b466ba1cf

games-util/pyfa/pyfa-2.37.0.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8..9} )
+PYTHON_REQ_USE="sqlite"
+
+inherit desktop edos2unix python-single-r1 xdg
+
+DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
+HOMEPAGE="https://github.com/pyfa-org/Pyfa"
+
+LICENSE="GPL-3+ all-rights-reserved"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/pyfa-org/Pyfa.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/pyfa-org/Pyfa/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/Pyfa-${PV}"
+fi
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="mirror bindist"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cryptography-2.3[${PYTHON_USEDEP}]
+		>=dev-python/logbook-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+		>=dev-python/wxpython-4.0.6[webkit,${PYTHON_USEDEP}]
+	')
+	${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/beautifulsoup-4.6.0[${PYTHON_USEDEP}]
+		>=dev-python/markdown2-2.3.5[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.19.2[${PYTHON_USEDEP}]
+		>=dev-python/packaging-16.8[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/roman-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.2.2[wxwidgets,${PYTHON_USEDEP}]
+	')"
+BDEPEND="app-arch/zip"
+
+PATCHES=(
+	# fix import path in the main script for systemwide installation
+	"${FILESDIR}/${PN}-2.9.3-import-pyfa.patch"
+)
+
+src_prepare() {
+	# get rid of CRLF line endings introduced in 1.1.10 so patches work
+	edos2unix config.py pyfa.py gui/bitmap_loader.py service/settings.py
+
+	default
+
+	# make python recognize pyfa as a package
+	touch __init__.py || die
+
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		-e "s:%%EPREFIX%%:${EPREFIX}:" \
+		"${FILESDIR}/configforced-1.15.1.py" > configforced.py || die
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		pyfa.py > pyfa || die
+}
+
+src_install() {
+	python_moduleinto ${PN}
+	python_domodule eos gui service utils graphs
+	python_domodule config*.py __init__.py version.yml configforced.py db_update.py
+	python_doscript pyfa
+
+	insinto /usr/share/${PN}
+
+	einfo "Creating database ..."
+	${EPYTHON} ./db_update.py || die
+	doins eve.db
+
+	einfo "Compressing images ..."
+	pushd imgs > /dev/null || die
+	zip -r imgs.zip * || die "zip failed"
+	doins imgs.zip
+	popd > /dev/null || die
+
+	dodoc README.md
+	doicon -s 32 imgs/gui/pyfa.png
+	newicon -s 64 imgs/gui/pyfa64.png pyfa.png
+	domenu "${FILESDIR}/${PN}.desktop"
+}