app-accessibility/simon: 0.4.90 version bump

Package-Manager: Portage-2.3.8, Repoman-2.3.3

app-accessibility/simon/Manifest

@@ -1 +1,2 @@
 DIST simon-0.4.1.tar.bz2 23856024 SHA256 8d55bc3f607a89e15efd51b844d93daf67d9967ad243f54efae324754859342d SHA512 d7349af3ec2482f18d8407891eeea7beea75630cc85aeade9f4105e3b84e82fde6284338688bbf84824d43c68de102eb34f3c21068cbe8a3307aa0586732b30d WHIRLPOOL 4c512bdfed8676cb5cfb896eacb14c66e3497abebe97a4faeb6804feb8ba36ed9101bc79a6efa573470d4a4d7eb6dfc94e3315dac488554563d35a397a066acb
+DIST simon-0.4.90.tar.xz 25257276 SHA256 e3a947c3b0b3f033cce43e2e7a5df86e0e8beec0442b2c19397f69f39a33307b SHA512 88b225e6d0168b87241649019376c8726fb3cc96ccbb985fd3dac5f5b67ed2d84de2756537300d7944797bceb7e340cdaf1c5aed731c1a7e2873d284ca3f94c1 WHIRLPOOL dca0174065a8c06269a02fdfdd6133e10e3f944ab2574259d1330b6210db5ddc381bd0f19f7566e225c0a73b3e2ba716e6fccbcf938e9a89f94cfbfba177f7c4

app-accessibility/simon/files/simon-0.4.1-libdir.patch

@@ -4,8 +4,8 @@ Subject: build system
 
 make libdir modifiable
 
---- simon-0.4.1/cmake/SimonDirs.cmake
-+++ simon-0.4.1/cmake/SimonDirs.cmake
+--- a/cmake/SimonDirs.cmake
++++ b/cmake/SimonDirs.cmake
 @@ -29,6 +29,6 @@
    #IF(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86_64")
      #set(SIMON_LIB_INSTALL_DIR lib64)

app-accessibility/simon/simon-0.4.90.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_LINGUAS="ast bs ca ca@valencia cs da de el en_GB es et fa fi fr ga gl
+hu ia ja kk lt mr nds nl pl pt pt_BR sk sl sv tr ug uk zh_CN zh_TW"
+SQL_REQUIRED="always"
+inherit kde4-base
+
+DESCRIPTION="Open-source speech recognition program for replacing mouse and keyboard"
+HOMEPAGE="http://simon-listens.org/"
+SRC_URI="mirror://kde/unstable/simon/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libsamplerate opencv sphinx"
+
+RDEPEND="
+	media-libs/alsa-lib
+	x11-libs/libX11
+	x11-libs/libXtst
+	x11-libs/qwt:6[qt4(+)]
+	libsamplerate? ( media-libs/libsamplerate )
+	opencv? ( media-libs/opencv )
+	sphinx? (
+		>=app-accessibility/pocketsphinx-0.8
+		>=app-accessibility/sphinxbase-0.8
+		>=app-accessibility/SphinxTrain-1
+	)
+	!sphinx? ( app-accessibility/julius )
+"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.4.1-libdir.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DSIMON_LIB_INSTALL_DIR=/usr/$(get_libdir)
+		-DWITH_KdepimLibs=OFF
+		-DUSE_PLASMA=OFF
+		-DWITH_LibSampleRate=$(usex libsamplerate)
+		-DWITH_OpenCV=$(usex opencv)
+		-DBackendType=$(usex sphinx "both" "jhtk")
+		$(cmake-utils_use_find_package sphinx Sphinxbase)
+		$(cmake-utils_use_find_package sphinx Pocketsphinx)
+	)
+
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	elog "Optional dependencies:"
+	elog "  kde-apps/jovie (support for Jovie TTS system)"
+	use sphinx && elog "  app-accessibility/julius (alternative backend)"
+}