app-emulation/winetricks: Sync with ::wine

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Nick Sarnie <[email protected]>

app-emulation/winetricks/Manifest

@@ -1,2 +1,3 @@
 DIST winetricks-20200412.tar.gz 684548 BLAKE2B e29eba0c73ec0649523dac0f0efd145a5c9fe60d94ae98bc55ec430f511cc5bdf3149d87289973a85a373f2f91c3bd5521470853e06f5ec4af83fc810aa4fdc5 SHA512 d6ca5628b7d296b3168ef088ca0b03aff8b73da8a139061ca64fac0685ec29bf2b7e075b89226f8ce3af511947eac45d4c72cfb1199e6b72666fc67547b77588
+DIST winetricks-20201206.tar.gz 690966 BLAKE2B 8304d64657fdd921974f0c326bb4e0e1d859a69e573a7387c945c7dbfd20540621cc9c89718069b569309ac2358872083d651d29ddce616d1c2cf9a12ed39943 SHA512 6965bea9bc8bb212fe2b851a53dd144c52b37466cd0d6d6a933e4e0c16b202647f1b19804159642ce9fda566872ca51e8326e8716fafdea43cd09f24ed6b4a25
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 BLAKE2B 54a4502f6e8ef15d21b02c43e3ce599e32d476c2559246064de14cc4ce2243ff11dde681d24c8a7f4913c3d7a10b855bda47e8fb8ecad31e00d839705416be6f SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a

app-emulation/winetricks/winetricks-20201206.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+wtg="winetricks-gentoo-2012.11.24"
+
+SRC_URI="${SRC_URI}
+	gtk? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+	kde? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="https://github.com/Winetricks/winetricks https://wiki.winehq.org/Winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar test"
+RESTRICT="!test? ( test )"
+
+# dev-util/shellcheck is not available for x86
+RESTRICT+=" x86? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/bashate
+		dev-util/checkbashisms
+		|| (
+			dev-util/shellcheck-bin
+			dev-util/shellcheck
+		)
+	)
+"
+DEPEND=""
+RDEPEND="${DEPEND}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	net-misc/wget
+	virtual/wine
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )
+"
+
+# Test targets include syntax checks only, not the "heavy duty" tests
+# that would require a lot of disk space, as well as network access.
+
+# This uses a non-standard "Wine" category, which is provided by
+# '/etc/xdg/menus/applications-merged/wine.menu' from the
+# 'app-emulation/wine-desktop-common' package.
+# https://bugs.gentoo.org/451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+
+	else
+		default
+	fi
+}
+
+src_test() {
+	./tests/shell-checks || die "Test(s) failed."
+}
+
+src_install() {
+	default
+
+	if ! use gtk && ! use kde; then
+		rm -r "${ED}"/usr/share/applications || die
+		rm -r "${ED}"/usr/share/icons || die
+	fi
+}

app-emulation/winetricks/winetricks-99999999.ebuild

@@ -1,9 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit desktop xdg
+inherit xdg
 
 if [[ ${PV} == "99999999" ]] ; then
 	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
@@ -84,10 +84,8 @@ src_test() {
 src_install() {
 	default
 
-	if use gtk || use kde; then
-		cd "${WORKDIR}/${wtg}" || die
-		domenu winetricks.desktop
-		insinto /usr/share/icons/hicolor/scalable/apps
-		doins wine-winetricks.svg
+	if ! use gtk && ! use kde; then
+		rm -r "${ED}"/usr/share/applications || die
+		rm -r "${ED}"/usr/share/icons || die
 	fi
 }