media-sound/qmmp: Bump to version 1.1.12

Package-Manager: Portage-2.3.12, Repoman-2.3.3
johu · Oct 23, 2017 · 15c7aea · 15c7aea
1 parent aee99c0
commit 15c7aea
Show file tree

Hide file tree

Showing 2 changed files with 147 additions and 0 deletions.
diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
@@ -1,3 +1,4 @@
 DIST qmmp-1.1.10.tar.bz2 1142444 SHA256 1e5781bf65b3a27dd5e21349ac007464e67861dda99f8a0206984687881e0b9a SHA512 f9945ea428265c900751dd692e25eb0618e162e621bda7ab5f0f77d504aee66fa06390edca0155d18ca041706f461dcb9bb20678eaf32250b766e0f593915356 WHIRLPOOL 1beaa2339fa8b86c79876774a3da12a8a5a62bf729e4fd6bd6896aa225bc573dc2272cc7438b257fe6567c8c85f38a301f2740eef788322e1d872404e5db6c0c
+DIST qmmp-1.1.12.tar.bz2 1147871 SHA256 4601898490167560e189a736ae619f6161cefd12a46252a9f151ec1bf7aac6da SHA512 a45680dcee478a7f03a04dbc87525368ac227a9de7e803252470f517027639d3426bf27a3235996d94ad68212596c03e7a67b5ad00a642532f02a820bf4097ee WHIRLPOOL a4babf407ae612d6604985a75ce905ae1e3cdc84899256c1a37e4daab3d395b435a1c64fd0b90e56545a84ab09d70ec32b2e495271b537738399f219cbe5f216
 DIST qmmp-1.1.7.tar.bz2 1135005 SHA256 464f79d9a54e6456c5abcb570d7f062e48d3eaa3d60ad2b09c58bc62af5b87a7 SHA512 058187d34b848c0917077a167bcb52c63e39b5150409295ea658484d99fcd5582f7871979d3d3eea40aa97f0d9bf2a2d72ae721b827bcc0366b1bbc652aa3a72 WHIRLPOOL 1c1f22a22329619f63a1a24590b41b352d398bb4653117c81918b2e940e887c6aaa06f178674a97893de7418673022bdc800a09643d3fb38096f6dc78b7774c3
 DIST qmmp-1.1.9.tar.bz2 1136753 SHA256 e25bfc0fb4182793df81c6ec222d553183ccd3f61e5919d217c9c5d788f3df2e SHA512 54ff71626b2ef778efef84fa56a50b483d6e9d14f1f53be2f1b01223a0f23db04fcc734a371eb22985404d9e15839b76c28d0909bf110c286ebbdf4ae27d1cd9 WHIRLPOOL 5fed1f1d3971887e3922d581e9805966c6715d834120218e013b5bb8b3e166ef89e21af6676ac642713370cfc54f6b0d62a47e5fa91445361cc5a59c749d0d1a
diff --git a/media-sound/qmmp/qmmp-1.1.12.ebuild b/media-sound/qmmp/qmmp-1.1.12.ebuild
@@ -0,0 +1,146 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.1"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game gnome
+jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="gnome? ( dbus ) udisks? ( dbus )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}