dev-lua/mediator_lua: migrate to lua eclass

Also adding tests. Bug: https://bugs.gentoo.org/628758 Closes: https://bugs.gentoo.org/752663 Package-Manager: Portage-3.0.9, Repoman-3.0.2 Signed-off-by: Conrad Kostecki <[email protected]>
johu · Nov 28, 2020 · 16fdc51 · 16fdc51
1 parent 370b392
commit 16fdc51
Show file tree

Hide file tree

Showing 3 changed files with 55 additions and 1 deletion.
diff --git a/dev-lua/mediator_lua/mediator_lua-1.1.2_p0-r100.ebuild b/dev-lua/mediator_lua/mediator_lua-1.1.2_p0-r100.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="${PV/_p/-}"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Mediator pattern implementation for pub-sub management "
+HOMEPAGE="http://olivinelabs.com/mediator_lua/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-lua/busted-2.0.0-r100
+		${RDEPEND}
+	)
+"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins src/mediator.lua
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/mediator_lua/metadata.xml b/dev-lua/mediator_lua/metadata.xml
@@ -5,7 +5,11 @@
 		<email>[email protected]</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>[email protected]</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		mediator_lua allows you to subscribe and publish to a central object so
 		you can decouple function calls in your application. It's as simple as
 		mediator:subscribe("channel", function). Supports namespacing, predicates,

diff --git a/profiles/package.mask b/profiles/package.mask
@@ -512,6 +512,7 @@ dev-lua/luacrypto
 >=dev-lua/luasocket-3.0_rc1_p20200328-r100
 >=dev-lua/lutok-0.4-r10
 >=dev-lua/luv-1.32.0.0-r100
+>=dev-lua/mediator_lua-1.1.2_p0-r100
 >=dev-lua/messagepack-0.3.2-r100
 >=dev-lua/penlight-1.9.2-r100
 >=dev-lua/say-1.3_p1-r100