games-emulation/fceux: add 2.6.0

Signed-off-by: Ionen Wolkens <[email protected]>

games-emulation/fceux/Manifest

@@ -1 +1,2 @@
 DIST fceux-2.5.0.tar.gz 21992303 BLAKE2B 2c467a92eaa53c846fdfc7c32c68bec75fdf45d5166f5fa7f1141c48f159c8dc6619f40861373ccb83718dd2d0b857c630f5101a1d29c2699adf128d4711a929 SHA512 bbff55b6f3efda8918b7dab21582d93f8c2a6396bf64a93e33f2f5f6cd345f95bcde7b958f0a663967e47e83110733c4a732dbf538afb7dbecb3147bc3090f01
+DIST fceux-2.6.0.tar.gz 22157111 BLAKE2B b65b44d82eba7aa4b51096a6a60d83095d01ee0931fe01ed523882db67eaa5d741b42ddabdbafe57b58df68949886e6b54ce7530d09704eb2c12dc30c22c623d SHA512 e79b53883918b7fd325575b07729d4b703b004de0c1408e1f5b37b87182b835ba755409303ef208ab4068f7d5c8d6887f9d4b325cca86a55860c9261539178bc

games-emulation/fceux/fceux-2.6.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 )
+inherit cmake lua-single xdg
+
+DESCRIPTION="Portable Famicom/NES emulator, an evolution of the original FCE Ultra"
+HOMEPAGE="https://fceux.com/"
+SRC_URI="mirror://sourceforge/fceultra/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ffmpeg x264 x265"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# TODO: QT6 support (disabled by default) when available in Gentoo
+RDEPEND="
+ ${LUA_DEPS}
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtopengl:5[-gles2-only]
+ dev-qt/qtwidgets:5
+ media-libs/libglvnd
+ media-libs/libsdl2[joystick,sound,threads,video]
+ sys-libs/zlib:=[minizip]
+ ffmpeg? ( media-video/ffmpeg:= )
+ x264? ( media-libs/x264:= )
+ x265? ( media-libs/x265:= )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.2.2-warnings.patch
+ "${FILESDIR}"/${PN}-2.4.0-desktop.patch
+ "${FILESDIR}"/${PN}-2.4.0-no-git.patch
+)
+
+src_prepare() {
+ cmake_src_prepare
+
+ use x264 || sed -i '/pkg_check_modules.*X264/d' src/CMakeLists.txt || die
+ use x265 || sed -i '/pkg_check_modules.*X265/d' src/CMakeLists.txt || die
+ use ffmpeg || sed -i '/pkg_check_modules.*LIBAV/d' src/CMakeLists.txt || die
+}
+
+src_install() {
+ local DOCS=( README TODO-SDL changelog.txt documentation/. readme.md )
+ cmake_src_install
+
+ # remove unused/duplicate files
+ rm "${ED}"/usr/share/fceux/{lua5{1,.1}.dll,{fceux,taseditor}.chm} \
+ "${ED}"/usr/share/doc/${PF}/fceux{,-net-server}.6 \
+ "${ED}"/usr/share/man/man6/fceux-net-server.6 || die
+}