app-editors/pyvim: new ebuild.

pyvim is an implementation of Vim in Python.

Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: Patrice Clement <[email protected]>

app-editors/pyvim/Manifest

@@ -0,0 +1 @@
+DIST pyvim-3.0.2.tar.gz 35227 BLAKE2B 8edc2218b3a0f2ba922531b75f65a5273ad9a2697f72ecf994cf7d2406c6311c3f28b22b6adb1243150a90db74962256ceaa7cf47ec99c2388299742451d6efb SHA512 da961342ba52e5beca44a607cbb923953388e8674409db9ca2b152017eeedce84f92e42a9f6d0e5019c5c4d88d82f4a987cb378f311cf84a169cefa54dc5efce

app-editors/pyvim/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>[email protected]</email>
+		<name>Gentoo Vim Project</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>[email protected]</email>
+		<name>Patrice Clement</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">pyvim</remote-id>
+		<remote-id type="github">prompt-toolkit/pyvim</remote-id>
+	</upstream>
+</pkgmetadata>

app-editors/pyvim/pyvim-3.0.2.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="An implementation of Vim in Python"
+HOMEPAGE="https://pypi.org/project/pyvim https://github.com/prompt-toolkit/pyvim"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	app-eselect/eselect-vi
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/docopt[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+	dev-python/pyflakes[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/prompt_toolkit[${PYTHON_USEDEP}]"
+
+eselect_vi_update() {
+	einfo "Calling eselect vi update..."
+	eselect vi update --if-unset
+	eend $?
+}
+
+pkg_postinst() {
+	eselect_vi_update
+}
+
+pkg_postrm() {
+	eselect_vi_update
+}