app-editors/gedit: Version bump to 42.0

Signed-off-by: Matt Turner <[email protected]>

app-editors/gedit/Manifest

@@ -1 +1,2 @@
 DIST gedit-41.0.tar.xz 6889320 BLAKE2B c4d2b923eab18cd27ffc0ff99882953e952c0956135fa7f6401ef01dd5cd0e1cf9a5a86c5751db9206fd88200c70434710881cd5b934a3620f14130a5066f18f SHA512 97c51ef24e53d6bd4b29350a8749eacbfcfb90b7c66c9f6d462101c53966282452f6a02043628e157e8179cf6260f103b41c61d7ba2a31da08b0687f8031974e
+DIST gedit-42.0.tar.xz 6923352 BLAKE2B 751c4cae8ad0c146f2607f259ab72f4723c433934f75356bf71e44daadc82d4403e19228b52ec2f98c3fa7bc61274a6ed648ef8af143adb7c89213d39db64473 SHA512 d0f3c05e0a6f96634cc2deb24d95d906e5bb9d380b248a810560b60ac8590831fb25672a41e143fe7bba3882a08ec7ec85208f896751a7b66cabe4ade00cdaca

app-editors/gedit/gedit-42.0.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_MIN_API_VERSION="0.26"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org gnome2-utils meson python-single-r1 vala xdg
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit https://gitlab.gnome.org/GNOME/gedit"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="+python gtk-doc spell"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.64:2
+	>=x11-libs/gtk+-3.22.0:3[introspection]
+	>=x11-libs/gtksourceview-4.0.2:4[introspection]
+	>=dev-libs/libpeas-1.14.1[gtk]
+	>=dev-libs/libxml2-2.5.0:2
+	>=dev-libs/gobject-introspection-1.54:=
+
+	spell? ( >=app-text/gspell-0.2.5:0= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pycairo[${PYTHON_USEDEP}]
+			>=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}]
+			dev-libs/libpeas[python,${PYTHON_SINGLE_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/gvfs
+"
+BDEPEND="
+	$(vala_depend)
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use python)
+		$(meson_feature spell)
+		-Duser_documentation=true
+		-Denable-gvfs-metadata=yes
+
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use python; then
+		python_optimize
+		python_optimize "${ED}/usr/$(get_libdir)/gedit/plugins/"
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}