www-apps/nikola: bump to v8.1.0

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Thomas Deutschmann <[email protected]>

www-apps/nikola/Manifest

@@ -1,2 +1,3 @@
 DIST Nikola-7.8.15.tar.gz 4131518 BLAKE2B ea3dca9340852a68b668de82e5deeaa0ecf7bb8597f311721b27409fe0cf820919c79f6e631b030bd3ea4571dd8480c862c607d0b9e6015a8b03023de5a9b93e SHA512 b441ae014539b948d007183ceb574243b89a498be265da7245095f67510d4d7c109c4935e0f9765b4144e82f788a1b66a0eacfba1477a89ce6c2645cb77102d7
 DIST Nikola-8.0.4.tar.gz 4137494 BLAKE2B 04db8b83f34ca9b3cee785c5eed9d0421d27acf750c4f17dc3bec0df6fd4f462af52a65c0c97a07777922da3bf3fa855d58d546479b19bfb152e8190d2f74524 SHA512 eb6774d11be4eab81fbe41115d80e5d0d38694b734431d5d6355fcd3e3d8ae5ff4a02114c5dd0dbbc9e1ea5a625e9ac2b6b91e82f6e017b4376e4ca8d56cfec7
+DIST Nikola-8.1.0.tar.gz 4298799 BLAKE2B 568b6b39506ab78c84bdb5fc1bf66829a714d41e1c88afe40236e915a801ce8214e7913ecfda7816d11af17beb9bdb54a0c60a88ef72ce53f7bdac91d057489d SHA512 b88fdf4848314e6428b7f3c4a891aefe682f1ae6a2cdc8da25de1d6af839f5d6f3410e23d90b76094f082aebe15d7e51b2c9cd079d017960bb979503d62a4b68

www-apps/nikola/nikola-8.1.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_PN="Nikola"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="https://getnikola.com/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="assets charts ghpages hyphenation ipython jinja watchdog webmedia websocket"
+RESTRICT="test" # needs coveralls
+
+DEPEND=">=dev-python/docutils-0.13[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${DEPEND}
+	>=dev-python/Babel-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.32[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/piexif-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/PyRSS2Gen-1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	assets? ( >=dev-python/webassets-0.10.1[${PYTHON_USEDEP}] )
+	charts? ( >=dev-python/pygal-2.0.1[${PYTHON_USEDEP}] )
+	ghpages? ( >=dev-vcs/ghp-import-0.4.1[${PYTHON_USEDEP}] )
+	hyphenation? ( >=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}] )
+	ipython? ( >=dev-python/ipython-2.0.0[notebook,${PYTHON_USEDEP}] )
+	jinja? ( >=dev-python/jinja-2.7.2[${PYTHON_USEDEP}] )
+	watchdog? ( >=dev-python/watchdog-0.8.3[${PYTHON_USEDEP}] )
+	webmedia? ( >=dev-python/micawber-0.3.0[${PYTHON_USEDEP}] )
+	websocket? ( ~dev-python/ws4py-0.3.4[${PYTHON_USEDEP}] )"
+#	typography? ( >=dev-python/typogrify-2.0.4[${PYTHON_USEDEP}] ) # needs smartypants
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-setup-py.patch
+)
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -rv "${D}/usr/share/doc/${PN}" || die
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.rst
+	gunzip "${D}/usr/share/man/man1/${PN}.1.gz" || die
+}