dev-python/pypax: version bump to 0.9.4, fixes bug #672072

Signed-off-by: Anthony G. Basile <[email protected]>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

dev-python/pypax/Manifest

@@ -1,2 +1,3 @@
 DIST elfix-0.9.2.tar.gz 398758 BLAKE2B 22f8d9e85be2ae9bd906dfa6a1d8b7614f017686b4563ef7e97898a112a56cff59a8cb906ec957b7a111a5c9251a3de6b13dfb66ef9f732099ac610928d5321e SHA512 a7be30722abe7249ec42024d33b2bda00524cfb85da66b4511c5056efbdbfae1d3c2b42048bcf4d5cb7c0ae675f763b74a834d93a25b541ebac42fddcd2c6cf9
 DIST elfix-0.9.3.tar.gz 399533 BLAKE2B 7ff2099218de3352079564971cd2e3851a95820552b9057387b78945fb1a23d7b670591b174dc974ca2b0dcf3948546578a210687cbb16625dc5d638abf83169 SHA512 3395ce2e6d5e9fc9bdd93b58751cea33b5fb8e25e0a390e6261de6804cc54d4e1f91b4b5843fc45c9178d86d23e9932bf9d0f133a6d086607bf52ce16c65fd0d
+DIST elfix-0.9.4.tar.gz 399606 BLAKE2B 51b8b2f1c3cce306c7bc0716ad351bbf446a369a353bcd1b5faa41984dec37e08dbeeea87fa2425820af9f76d36209554b8e602338d01d0ad50e6d95e6079529 SHA512 f705f63b0ca57077f56e519a22ccaeb2e07f57c5269a6e498571a1799286f12098ccc9a92d2126b51b498447a098b0ce22d54c0d97c8c98d25426fe1e00c6e07

dev-python/pypax/pypax-0.9.4.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy )
+
+inherit distutils-r1
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/elfix.git"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~blueness/elfix/elfix-${PV}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+	S="${WORKDIR}/elfix-${PV}"
+fi
+
+DESCRIPTION="Python module to get or set either PT_PAX and/or XATTR_PAX flags"
+HOMEPAGE="https://dev.gentoo.org/~blueness/elfix/
+	https://www.gentoo.org/proj/en/hardened/pax-quickstart.xml"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+ptpax +xtpax"
+
+REQUIRED_USE="|| ( ptpax xtpax )"
+
+RDEPEND="
+	ptpax? ( dev-libs/elfutils )
+	xtpax? ( sys-apps/attr )"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${RDEPEND}"
+
+src_compile() {
+	cd scripts || die
+	unset PTPAX
+	unset XTPAX
+	use ptpax && export PTPAX="yes"
+	use xtpax && export XTPAX="yes"
+	distutils-r1_src_compile
+}
+
+src_install() {
+	cd scripts || die
+	distutils-r1_src_install
+}