media-gfx/displaycal: 3.4.0.0 bump

Closes: https://bugs.gentoo.org/642994
Package-Manager: Portage-2.3.19, Repoman-2.3.6

media-gfx/displaycal/Manifest

@@ -1 +1,2 @@
 DIST DisplayCAL-3.3.5.0.tar.gz 9913672 BLAKE2B de95217baf18a3b07b51a9db24e37cd965ecf5ba96392410f7f5af788b696f69260eac5c0188cbd3a2f1b90dfafe781cd711c04a9bd45dd5a2fa59fd547087b2 SHA512 7a24cbc540771fd26b504536ee0c1b9c34f013c19b5b2a4e1ce38015014e9b34e67b48a1f08bf96581cef2968883691206ddb6cefa9ac70d76251a305a5b1c37
+DIST DisplayCAL-3.4.0.0.tar.gz 10279645 BLAKE2B cf0b6d841c26d8ee4eec47fa58071e31e1ae4c8f1cd63f08216dbfd33caeb900d767988aa19f1738bdbe3c180954a13be22fdd96187b32edc8b0419b945670be SHA512 a63cda986a70cef844908c5809157af28473b564c97fa4c1b957102401b177b254cd215b1cb7c8192873e6d1b204dca66f5a08862f27e0d2f0c06b6ceeaae25e

media-gfx/displaycal/displaycal-3.4.0.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 gnome2-utils xdg
+
+MY_PN="DisplayCAL"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Display calibration and characterization powered by Argyll CMS"
+HOMEPAGE="https://displaycal.net/"
+SRC_URI="mirror://sourceforge/dispcalgui/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=media-gfx/argyllcms-1.1.0
+	dev-python/wxpython:3.0
+	>=x11-libs/libX11-1.3.3
+	>=x11-apps/xrandr-1.3.2
+	>=x11-libs/libXxf86vm-1.1.0
+	>=x11-proto/xineramaproto-1.2
+	>=x11-libs/libXinerama-1.1
+"
+RDEPEND="${DEPEND}
+	>=dev-python/numpy-1.2.1
+"
+
+# Just in case someone renames the ebuild
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Do not generate udev/hotplug files
+	sed -e '/if os.path.isdir/s#/etc/udev/rules.d\|/etc/hotplug#\0-non-existant#' \
+		-i DisplayCAL/setup.py || die
+	# Prohibit setup from running xdg-* programs, resulting to sandbox violation
+	sed -e '/if which/s#xdg-icon-resource#\0-non-existant#' \
+		-e '/if which/s#xdg-desktop-menu#\0-non-existant#' \
+		-i DisplayCAL/postinstall.py || die
+
+	# Remove deprecated Encoding key from .desktop file
+	sed -e '/Encoding=UTF-8/d' -i misc/*.desktop  || die
+
+	# Remove x-world Media Type
+	sed -e 's/x\-world\/x\-vrml\;//g' \
+		-i misc/displaycal-vrml-to-x3d-converter.desktop || die
+
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+}