media-video/subliminal: Support python3.6

Package-Manager: Portage-2.3.40, Repoman-2.3.9

media-video/subliminal/Manifest

@@ -1,2 +1,3 @@
 DIST matroska_test_w1_1.zip 184550509 BLAKE2B f111725aa08267661942072c2d4ac019d3d322c4e933aad10afb3aa6f69bb3469114c4400d161e53d8a7618b818b22465177460003804a7ac3e69fa4f4db000d SHA512 f170a8e83dab15228f992b3692330163da2402b8e436c7fa195ac1ecc06cf1eaf1a48d8c99a85c031122c158c2d4006023aae75d5b7805385ba25a6d601cb78f
 DIST subliminal-2.0.5-r1.tar.gz 4442435 BLAKE2B ea2139bd61344d6a0cb4b48a2b75cbfd29905adc81bca25a332443725fff80bc03b58704d0e6289d44ddc26104e15744f67acb7e0e4eafae584098b02fb4c007 SHA512 b0f99c6b2fa6bc3860c86592bb428c7b4b34836df7a619b19d69b15532a68b4d05369f724131e120d4b390bd91f430aea442aef72ebc00ae8e3d31a457925eec
+DIST subliminal-2.0.5-r2.tar.gz 4442435 BLAKE2B ea2139bd61344d6a0cb4b48a2b75cbfd29905adc81bca25a332443725fff80bc03b58704d0e6289d44ddc26104e15744f67acb7e0e4eafae584098b02fb4c007 SHA512 b0f99c6b2fa6bc3860c86592bb428c7b4b34836df7a619b19d69b15532a68b4d05369f724131e120d4b390bd91f430aea442aef72ebc00ae8e3d31a457925eec

media-video/subliminal/subliminal-2.0.5-r2.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+PYTHON_REQ_USE='xml(+)'
+COMMIT_ID='dd74383d1cba82829ce720f2e439a65d13ffe7ef'
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="Python library to search and download subtitles"
+HOMEPAGE="https://github.com/Diaoul/subliminal https://pypi.org/project/subliminal/"
+SRC_URI="
+	https://github.com/Diaoul/${PN}/archive/${COMMIT_ID}.tar.gz -> ${PF}.tar.gz
+	test? ( mirror://sourceforge/matroska/test_files/matroska_test_w1_1.zip )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/guessit-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/babelfish-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/enzyme-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.4.0:4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0[${PYTHON_USEDEP}]
+	>=dev-python/click-4.0[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pysrt-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3[${PYTHON_USEDEP}]
+	>=dev-python/rarfile-2.7[compressed,${PYTHON_USEDEP}]
+	>=dev-python/pytz-2012c[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		app-arch/unzip
+		>=dev-python/vcrpy-1.6.1[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+	)
+"
+
+# Tests don't work in 2.0.5. Recheck in later versions. See Gentoo bug 630114.
+RESTRICT=test
+
+PATCHES=( "${FILESDIR}/${P}-add-missing-comma.patch" )
+
+S="${WORKDIR}/${PF}"
+
+python_prepare_all() {
+	# Disable code checkers as they require unavailable dependencies.
+	sed -i -e 's/--\(pep8\|flakes\)//g' pytest.ini || die
+	sed -i -e "s/'pytest-\(pep8\|flakes\)',//g" setup.py || die
+
+	# Disable unconditional dependency on dev-python/pytest-runner.
+	sed -i -e "s|'pytest-runner'||g" setup.py || die
+
+	if use test; then
+		mkdir -p tests/data/mkv || die
+		ln -s "${WORKDIR}"/test*.mkv tests/data/mkv/ || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}