app-i18n/ibus-typing-booster: new upstream release

Signed-off-by: Akinori Hattori <[email protected]>

app-i18n/ibus-typing-booster/Manifest

@@ -1 +1,2 @@
 DIST ibus-typing-booster-2.21.4.tar.gz 11220794 BLAKE2B 7e5c7b9be31858ce1be7399b7dbada4cdec5a24f9d4f66d4e5ea110153d4696aa794650048b40dc52044ad90514f051a60234835d9b3c59aadb05aa6ba9eef4b SHA512 26dbc8cee8e6a6ec0414fc3e2f26298665030babed7f7dba7f52b5260b9aba511ab456fe49fb779f66b66b4db9fbe81faeec8692ad8a101e518d6fcf80189fd8
+DIST ibus-typing-booster-2.22.1.tar.gz 11322188 BLAKE2B f9119aecd57c1f6581035548c53ceda529cee67636760bca0540e9fd91d92440fa3f8df5fb1065db2a131d20942519482f6b7cbee1cc7f74c58e01344bf07fa1 SHA512 c979c1e58c038ba6b5a07223e74c080f8d5f2c45b9f60c279aba49bb98c51a13b8922f5c167a2bfd07ccd9c7dbdf56ff784379124f6425ead0d16cc9dd5ced43

app-i18n/ibus-typing-booster/ibus-typing-booster-2.22.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Completion input method for IBus"
+HOMEPAGE="https://mike-fabian.github.io/ibus-typing-booster"
+SRC_URI="https://github.com/mike-fabian/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	dev-libs/m17n-lib
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pyenchant[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	')"
+RDEPEND="${DEPEND}
+	>=dev-db/m17n-db-1.7"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i "s|/usr\(/bin/sh\)|\1|" {engine,setup}/*.in
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}