dev-python/flask-nav: bump to 0.6

Package-Manager: portage-2.3.2
Closes: gentoo#2945

dev-python/flask-nav/Manifest

@@ -1 +1,2 @@
 DIST flask-nav-0.5.tar.gz 11579 SHA256 68a608aae8c6c21453247cc288595c9d52a6b5f3bc31d9a9ee3fd7a1f9c28c47 SHA512 94ebd858754c0ac936b43762cf427c381faa40de86e73b487d6b415d099696e6216b96ad9fefa62516cefd8e51e7ef282e01e1a492783ab696a9fd3602de7e78 WHIRLPOOL f47f6773fd31e4a959437159c5de88f6463ad890e36387cf205ffd42d4de41f375f8264f568bd192ad4f8235cf6e5a6651c2ca3b5dbf14a785f749ab8510a098
+DIST flask-nav-0.6.tar.gz 12270 SHA256 53c7c97cbc75ab904389331a7c8870314c040a668914c3554aa77dcd36609f86 SHA512 a7930687425a53fac9ad9a7cb65c2e2a759a0c9660189965bf37ea6e9925dd869074d37a283801631b3e6c3391f9f4167e0a36294104f72970e876b5a7a0930c WHIRLPOOL e29e32bc4c49049bc0660df9e0ba6737ee48f1841b34314b937b5b41b443d4fb0fccc3e9c5502f68a0486b8eb2218a6a9539b22892af4d65e47019669d46864a

dev-python/flask-nav/flask-nav-0.6.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Easily create navigation for Flask applications."
+HOMEPAGE="https://pythonhosted.org/flask-nav/"
+# docs are missing from PyPI tarballs
+# https://github.com/mbr/flask-nav/pull/12
+SRC_URI="https://github.com/mbr/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/dominate[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/visitor[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}