dev-vcs/gitstats: fix the live ebuild's repo URI, license, dependenci…

…es, docs

The following changes have been made:
- eapi bump to EAPI 6
- inherit git-r3 instead of the obsolete git-2
- fix EGIT_REPO_URI
- fix LICENSE
  - the homepage has the following:
    "Both the code and the web site are licensed under GPLv2/GPLv3."
    So, use '|| ( GPL-2 GPL-3 )'
  - there's a bunled javascript file 'sortable.js' which is licensed under MIT
- add the missing build time dependency on perl
- install docs and manpage

Package-Manager: portage-2.2.26
Acked-by: Guilherme Amadio <[email protected]>
Closes: gentoo#972

dev-vcs/gitstats/gitstats-9999.ebuild

@@ -1,42 +1,49 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 PYTHON_COMPAT=( python2_7 )
 
-inherit python-r1 git-2
+inherit python-r1 git-r3
 
 DESCRIPTION="Statistics generator for git"
 HOMEPAGE="http://gitstats.sourceforge.net/"
 SRC_URI=""
 EGIT_REPO_URI="
-	git://repo.or.cz/${PN}.git
-	http://repo.or.cz/r/${PN}.git"
+	git://github.com/hoxu/gitstats.git
+	https://github.com/hoxu/gitstats.git
+"
 
-LICENSE="GPL-3"
+LICENSE="|| ( GPL-2 GPL-3 ) MIT"
 SLOT="0"
 KEYWORDS=""
 IUSE=""
 
 RDEPEND="
 	sci-visualization/gnuplot[gd]
 	dev-vcs/git"
-DEPEND=""
+DEPEND="
+	dev-lang/perl:*
+"
+
+DOCS=( doc/{AUTHOR,README,TODO.txt} )
 
 src_prepare() {
 	sed \
-		-e "s:basedir = os.path.dirname(os.path.abspath(__file__)):basedir = '${EPREFIX}/usr/share/gitstats':g" \
+		-e "s:basedirs = \[binarypath, secondarypath, '/usr/share/gitstats'\]:basedirs = \['${EPREFIX}/usr/share/gitstats'\]:g" \
 	-i gitstats || die "failed to fix static files path"
+	default
 }
 
 src_compile() {
-	:;
+	emake VERSION="${PV}" man
 }
 
 src_install() {
-	emake PREFIX="${D}"/usr VERSION="${PV}" install
-	dodoc doc/{README,*.txt}
-	python_replicate_script "${ED}"/usr/bin/${PN}
+	emake PREFIX="${ED}"usr VERSION="${PV}" install
+	doman doc/${PN}.1
+	einstalldocs
+	python_replicate_script "${ED}"usr/bin/${PN}
 }