dev-util/clion: version bump to 2020.1.2

Package-Manager: Portage-2.3.99-r2, Repoman-2.3.22
Signed-off-by: Christian Strahl <[email protected]>

Closes: https://bugs.gentoo.org/728414
Signed-off-by: Joonas Niilola <[email protected]>

dev-util/clion/Manifest

@@ -1 +1,2 @@
 DIST clion-2020.1.1.tar.gz 510085810 BLAKE2B c80b1dd6c88e89803f73dc22cf6d942a783a4d8a607904ffe44b445ab998f9f7db4aa6233305e617cb91608934ec86be208d798f512a849dbf98738293f8ff73 SHA512 3807d651b8b5b1c8c30658514f3aa376019bfebefff724375ae54d9105fcd9db370023906b51af2debcf83d26cebb060c88e228e7b672ad181e73a77d1ed4016
+DIST clion-2020.1.2.tar.gz 509953307 BLAKE2B f4f3ed6478b8b17e7efa14932156da8087c71b850b2b08340b3d5fc9c39d84c547bd8d2ef194117609a6e9bcb85396796661ad70beb478a0579a85a25ec5d503 SHA512 68348a20a18f681298e0e1207c1794a437d58dd52d700ed7f3935e2434672b7648b0e6414b25e32fa3929a9c6973dd3024448dd514ffe05690826d02760fa4c3

dev-util/clion/clion-2020.1.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils
+
+DESCRIPTION="A complete toolset for C and C++ development"
+HOMEPAGE="https://www.jetbrains.com/clion"
+SRC_URI="https://download.jetbrains.com/cpp/CLion-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( IDEA IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )
+	Apache-1.1 Apache-2.0 BSD BSD-2 CC0-1.0 CDDL-1.1 CPL-0.5 CPL-1.0
+	EPL-1.0 EPL-2.0 GPL-2 GPL-2-with-classpath-exception GPL-3 ISC JDOM
+	LGPL-2.1+ LGPL-3 MIT MPL-1.0 MPL-1.1 OFL public-domain PSF-2 UoI-NCSA ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist mirror splitdebug"
+IUSE="custom-jdk"
+
+# RDEPENDS may cause false positives in repoman.
+# clion requires cmake and gdb at runtime to build and debug C/C++ projects
+RDEPEND="
+	dev-libs/libdbusmenu
+	dev-util/cmake
+	sys-devel/gdb
+	!custom-jdk? ( virtual/jdk )"
+
+QA_PREBUILT="opt/${P}/*"
+
+src_prepare() {
+	default
+
+	local remove_me=(
+		bin/gdb/linux
+		bin/lldb/linux
+		bin/cmake
+		license/CMake*
+		lib/pty4j-native/linux/ppc64le
+	)
+
+	use amd64 || remove_me+=( bin/fsnotifier64 lib/pty4j-native/linux/x86_64)
+	use x86 || remove_me+=( bin/fsnotifier lib/pty4j-native/linux/x86)
+
+	use custom-jdk || remove_me+=( jbr )
+
+	rm -rv "${remove_me[@]}" || die
+}
+
+src_install() {
+	local dir="/opt/${P}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{clion.sh,clang/linux/clang{d,-tidy}}
+
+	if use amd64; then
+		fperms 755 "${dir}"/bin/fsnotifier64
+	fi
+	if use arm; then
+		fperms 755 "${dir}"/bin/fsnotifier-arm
+	fi
+	if use x86; then
+		fperms 755 "${dir}"/bin/fsnotifier
+	fi
+
+	if use custom-jdk; then
+		if [[ -d jbr ]]; then
+		fperms 755 "${dir}"/jbr/bin/{jaotc,java,javac,jdb,jjs,jrunscript,keytool,pack200,rmid,rmiregistry,serialver,unpack200}
+		fi
+	fi
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.svg" "${PN}.svg"
+	make_desktop_entry "${PN}" "clion" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	dodir /usr/lib/sysctl.d/
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
+}