dev-util/ctags: add 20230423.0

Signed-off-by: Sam James <[email protected]>

dev-util/ctags/Manifest

@@ -1,2 +1,3 @@
 DIST ctags-20211017.0.tar.gz 2542128 BLAKE2B cade7149cb2fd0645f9b7ecd37c8b9acdeae7037fde2bb74aa94d67f04963327429b83dcf5cd658f082bd8ce4c407f69f4924da5f768bec029b4075997bbd882 SHA512 85bfb4d40c1d9045b4ba4dc280ee7108ee2fd4572c92794d5bdc854f3511dad1ecf282428e61161773f7bfaca725d774593a0e83fc767a1bb2e12b229a19bec0
 DIST ctags-20220828.0.tar.gz 2952276 BLAKE2B 2ec3a01646cfb89446604af65387bb5cbf17188177505000f5803a9a535f59799961e8144d3ab36b23114fc093cb487589f52e7186b60041ff3bf2a439f77dab SHA512 4c1289dab24edded85c7ae31c06b0cad5b8f08f7f709a0bdacdf5f9d8ccf722c820d6fef6d46298bb06c48256e80f594dbf2456b91d1c50b3509ce4d3fe3ae9c
+DIST ctags-20230423.0.tar.gz 3038197 BLAKE2B 4b6114526e9dc94c95dcf1b27136fe1fde185aadcd3f880459314b6567f4ec935da10f87aaad590f4c16999adea8b15b3a153f4e80b3b9e57d9a04ecee377a09 SHA512 7a4b3ffcc4906765dda381ad637981f5ce8c6fc24d4141b8b0e9997b71767dda307dab4d2c2aa0e5ba003774c100d8f85e494e368cedbef12c8f415a13b85554

dev-util/ctags/ctags-20230423.0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit autotools python-any-r1
+
+DESCRIPTION="Exuberant Ctags creates tags files for code browsing in editors"
+HOMEPAGE="https://ctags.io/ https://github.com/universal-ctags/ctags"
+
+if [[ ${PV} == *99999999* ]] ; then
+	EGIT_REPO_URI="https://github.com/universal-ctags/ctags"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/universal-ctags/ctags/archive/refs/tags/p6.0.${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-p6.0.${PV}
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="json pcre seccomp test xml yaml"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	json? ( dev-libs/jansson:= )
+	pcre? ( dev-libs/libpcre2 )
+	seccomp? ( sys-libs/libseccomp )
+	xml? ( dev-libs/libxml2:2 )
+	yaml? ( dev-libs/libyaml )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-python/docutils
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+IDEPEND="app-eselect/eselect-ctags"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Ignore check-genfile test (calls git which errors out)
+	sed -i 's/man-test check-genfile/man-test/' makefiles/testing.mak || die
+
+	default
+
+	#./misc/dist-test-cases > makefiles/test-cases.mak || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable json) \
+		$(use_enable pcre pcre2) \
+		$(use_enable seccomp) \
+		$(use_enable xml) \
+		$(use_enable yaml) \
+		--disable-etags \
+		--enable-tmpdir="${EPREFIX}"/tmp
+}
+
+src_install() {
+	emake prefix="${ED}"/usr mandir="${ED}"/usr/share/man install
+
+	# Namepace collision with X/Emacs-provided /usr/bin/ctags -- we
+	# rename ctags to exuberant-ctags (Mandrake does this also).
+	mv "${ED}"/usr/bin/{ctags,exuberant-ctags} || die
+	mv "${ED}"/usr/share/man/man1/{ctags,exuberant-ctags}.1 || die
+}
+
+pkg_postinst() {
+	eselect ctags update
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "You can set the version to be started by ${EROOT}/usr/bin/ctags through"
+		elog "the ctags eselect module. \"man ctags.eselect\" for details."
+	fi
+}
+
+pkg_postrm() {
+	eselect ctags update
+}

dev-util/ctags/ctags-99999999.ebuild

@@ -13,8 +13,8 @@ if [[ ${PV} == *99999999* ]] ; then
 	EGIT_REPO_URI="https://github.com/universal-ctags/ctags"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/universal-ctags/ctags/archive/refs/tags/p5.9.${PV}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}"/${PN}-p5.9.${PV}
+	SRC_URI="https://github.com/universal-ctags/ctags/archive/refs/tags/p6.0.${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-p6.0.${PV}
 
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 fi