media-sound/mpc: Add USE doc, fix install path

Closes: https://bugs.gentoo.org/670074 Closes: https://bugs.gentoo.org/670262 Package-Manager: Portage-2.3.59, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <[email protected]>
johu · Feb 9, 2019 · 35999ae · 35999ae
1 parent 5db57cd
commit 35999ae
Showing 1 changed file with 54 additions and 0 deletions.
diff --git a/media-sound/mpc/mpc-0.31-r1.ebuild b/media-sound/mpc/mpc-0.31-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 meson
+
+DESCRIPTION="Commandline client for Music Player Daemon (media-sound/mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/mpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc iconv test"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+	iconv? ( virtual/libiconv )
+	test? ( dev-libs/check )
+"
+DEPEND="media-libs/libmpdclient"
+RDEPEND="${DEPEND}"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}/${P}-nodoc.patch" )
+
+src_prepare() {
+	default
+
+	# use correct docdir
+	sed -e "/install_dir:.*contrib/s/meson.project_name()/'${PF}'/" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Diconv=$(usex iconv enabled disabled)
+		-Dtest=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	newbashcomp contrib/mpc-completion.bash mpc
+}