gnome-base/gnome-desktop: bump to 3.36.5

Package-Manager: Portage-2.3.103, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <[email protected]>

gnome-base/gnome-desktop/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-desktop-3.34.7.tar.xz 718220 BLAKE2B 89bfd00a356cd47d865aa4df1079b37b08c6a85f4380b5424181ce247248c7f11f0ca135858afb0c00fc4ff47175ff2acbb0b67cebe75e0b0a9f27263f0a9d69 SHA512 efc466d2a7a8a142e76a07c8cb75bad51aafbb2e70432e339713965890e6a83554a5f77ef6cdb6aa9e3ebace4883fb6d3d06004d7a2446d6960319cacbec7639
 DIST gnome-desktop-3.36.4.tar.xz 736324 BLAKE2B 68abef71e1732f72eabc6cac83b513af30d8cd39f92baaa57757bb818f8309a82a1ed8dcecef6015d6b8fb08f24e2ab041ccb796955c599a4cf43c412dd0c147 SHA512 06683df9a774487f386cf5aece586fb9666fdebfe5c9ea247e6ab91f6f281ca0241b13e9eb4e0eda1fb856b9cf1109fea859964998df2e2b06c8861efc76316f
+DIST gnome-desktop-3.36.5.tar.xz 738956 BLAKE2B 6c419df487e908f57a1dc8798a8dfe8b574d8c5c9aa5d83e45aed233ba856ba398367a990aa83fb1b8966aad02c868cd0e41805908863ea8fef24cc3ade3687c SHA512 0b5ad42c0832d58552270e9e24dabf56668c4fbb84d07812e4a2a34cff0a67344a7c8ee963a53a703b2e4bb28c67035bf2ce854ea271194511dc66e051481b1b

gnome-base/gnome-desktop/gnome-desktop-3.36.5.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# cairo[X] needed for gnome-bg
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	app-text/iso-codes
+	x11-libs/libX11
+	systemd? ( sys-apps/systemd:= )
+	udev? (
+		sys-apps/hwids
+		virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=[X]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	x11-base/xorg-proto
+	virtual/pkgconfig
+"
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
+
+PATCHES=(
+	"${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
+)
+
+src_prepare() {
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}