gnome-extra/gnome-documents: bump to 3.34.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <[email protected]>

gnome-extra/gnome-documents/Manifest

@@ -1 +1,2 @@
 DIST gnome-documents-3.30.1.tar.xz 4777500 BLAKE2B 889a089e4968e233185a6018559487e0cede40bbe789bee3e1eaab3283bf66f797dbcf7281361432d0b3a41b68b1914efbfb5be4875fa1986cbe3241a40cbcb5 SHA512 89966d49ececa11ab49eb0e192c6a1d398ef13f2f809a02cca2d13f7ffa4cef45a29801971edec22d2f471ab4291a058c702842e323cb2a1ddd7fcc37d51b6cb
+DIST gnome-documents-3.34.0.tar.xz 914100 BLAKE2B 5b59931d488a5b3d3b2940852b64b0af3cff71c685d62e07bee5d0e981e9a78bb913db853c0c3f138ea1728d2ff7495b689f1f5509064131ee2a4649e65d527f SHA512 5867b148aaffd02089e4f1148cf0fbce37ba0ed40c7d255f9261cd225757f56b68293d59476ab7c11ebbe310cc7935081b2770e7bc24bdbddb5934da5ea0cf87

gnome-extra/gnome-documents/gnome-documents-3.34.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="A document manager application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Documents"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+KEYWORDS="~amd64 ~x86"
+
+# cairo-1.14 for cairo_surface_set_device_scale check and usage
+COMMON_DEPEND="
+	>=app-text/evince-3.13.3[introspection]
+	app-misc/tracker:0/2.0
+	>=dev-libs/gjs-1.48.0
+	>=dev-libs/glib-2.39.3:2
+	gnome-base/gnome-desktop:3=[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.22.15:3[introspection]
+	>=net-libs/libsoup-2.41.3:2.4
+	>=net-libs/webkit-gtk-2.6:4[introspection]
+
+	>=dev-libs/libgdata-0.13.3:=[crypt,gnome-online-accounts,introspection]
+	>=net-libs/gnome-online-accounts-3.2.0[introspection]
+	>=net-libs/libzapojit-0.0.2[introspection]
+
+	>=x11-libs/cairo-1.14
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/pango[introspection]
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-misc/tracker-miners-2
+	net-misc/gnome-online-miners
+	sys-apps/dbus
+	x11-themes/adwaita-icon-theme
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=true #manpage
+		-Dgetting_started=false #inkscape and pdfunite build deps
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}