dev-util/kbuild: Bump to version 0.1.9998.3127

The fourth version component is now the svn revision as this needs to be
added to some of the binaries in order to get recent virtualbox releases
built.

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-util/kbuild/Manifest

@@ -1,3 +1,4 @@
 DIST kBuild-0.1.9998-pre20131130-src.tar.xz 1707632 BLAKE2B 51d68203d38a6cc86a32e6c66431739a87df738e920bfc9ff902433a46279fd62c704d9bcae02f0a1cb6a1f97cf68dab059c636ebd425d2b15c50c9c9cb4fcc6 SHA512 66f418c0e052389d2b5cfc4d46bc8598ceaeded369151047e455e921bef494ec42099cdc368d24b572eacd809bb7c124d07e0fab54788af01664b72f571fb047
+DIST kbuild-0.1.9998.3127-src.tar.xz 2221336 BLAKE2B 12eb542553c2abe4419440d124ed9c6b3c485fc77ca20bc8b8d5265cf2d91003e3bee21ad7e247f1da43c88bd29fdc5d317e42bfca213cde1ac0c900cce03fcf SHA512 b4cfca917efdb19b015a70efc15fdb0f2f08a4b6e493c7ac121dada97866b2f57cb9be9db9dd9b337eda4d5772ab850bf0586e5bfdc370e1332659363374f78d
 DIST kbuild-0.1.9998_pre20131130-tools_and_units_updates.patch.xz 7344 BLAKE2B 75d24ba49ee69a11b8e1d798ebee4470fa50ec4970299faaa67b0537d21729053fa24142d02e428cb56c429c6c17d581d147d659c3a3ad11693e2fa6ab4e6d72 SHA512 91aac638e9f4cc321f7d06c89be1a4ce4e57aa88165c71a4f68a73ad51f049f631b2d7427178014408b551fac5678f0c0bf806a61f9d749daf5019f1b6a61bb0
 DIST kbuild-0.1.9998_pre20171020-src.tar.xz 2190856 BLAKE2B 3918170fdda00ab65136da0deacfe6a2e779a8bcca0b1a565f89f367ac4d73feb8566157b7cfdf2d38beb5864f9dde1010420cf4b03ff71b455f99744096c37b SHA512 53c55a520f3711d1141b10eaeb3bec5dc57bb8476c6b658826e05dbb525eda43a0007dd94dcdde31ea39ad0bb29223ef8ad2a72da1404e53919e444039794043

dev-util/kbuild/kbuild-0.1.9998.3127.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils autotools toolchain-funcs versionator
+
+MY_P="${P}-src"
+DESCRIPTION="A makefile framework for writing simple makefiles for complex tasks"
+HOMEPAGE="http://svn.netlabs.org/kbuild/wiki"
+#SRC_URI="ftp://ftp.netlabs.org/pub/${PN}/${MY_P}.tar.gz"
+SRC_URI="https://dev.gentoo.org/~polynomial-c/${MY_P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE=""
+
+DEPEND="
+	sys-apps/texinfo
+	sys-devel/flex
+	sys-devel/gettext
+	virtual/yacc
+"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}/${PN}-unknown-configure-opt.patch"
+	"${FILESDIR}/${PN}-0.1.5-gentoo-docdir.patch"
+	"${FILESDIR}/${PN}-0.1.9998_pre20120806-qa.patch"
+	"${FILESDIR}/${PN}-0.1.9998_pre20110817-kash-link-pthread.patch"
+	"${FILESDIR}/${PN}-0.1.9998_pre20171020-gold.patch"
+)
+
+src_prepare() {
+	rm -rf "${S}/kBuild/bin"
+
+	default
+
+	mv src/kmk/configure.{in,ac} || die
+
+	# Add a file with the svn revision this package was pulled from
+	printf '%s\n' "KBUILD_SVN_REV := $(get_version_component_range 4)" \
+		> SvnInfo.kmk || die
+
+	cd "${S}/src/kmk" || die
+	eautoreconf
+	cd "${S}/src/sed" || die
+	# AM_CONFIG_HEADER is obsolete since automake-1.13 (bug #467104)
+	sed 's@AM_CONFIG_HEADER@AC_CONFIG_HEADERS@' -i configure.ac || die
+	eautoreconf
+
+	sed -e "s@_LDFLAGS\.$(tc-arch)*.*=@& ${LDFLAGS}@g" \
+		-i "${S}"/Config.kmk || die #332225
+	tc-export CC RANLIB #AR does not work here
+}
+
+src_compile() {
+	kBuild/env.sh --full emake -f bootstrap.gmk AUTORECONF=true AR="$(tc-getAR)" \
+		|| die "bootstrap failed"
+}
+
+src_install() {
+	kBuild/env.sh kmk NIX_INSTALL_DIR=/usr PATH_INS="${D}" install \
+		|| die "install failed"
+}