dev-libs/check: 0.15.0 release

Signed-off-by: Joonas Niilola <[email protected]>

dev-libs/check/Manifest

@@ -1 +1,2 @@
 DIST check-0.14.0.tar.gz 303471 BLAKE2B d602bb56d205eccf06e4177e3f6d3f7270c3a0cba0e1d397480f0409a916ec4118c48340ad6f6a8955ea30d9e22252ff8381a687d000c3f8e62828cf656f1245 SHA512 54ad175c00cf0c73b4386cf6b3d6a404a5da4f57897d099e772f148f410108c44767c3266a940113be73a6861b3f3ee1706c558cc71ec51df99687f19f3a3bb4
+DIST check-0.15.0.tar.gz 306428 BLAKE2B fea2a169b86248a6657f890469f41cd699dd95efb91e311ccf188548a6c8c28568decf0b5f03b08aed31e14c69d50707b418e1e71c6db7e1b7938ee36aa19cd8 SHA512 efde93977a38520b3b83a9e2f678d07b916fc27e41cf839a663900c4153d645fe4274ec3b7e2dabf475457f909f61734632c97b7257c49f5853fd11d920b0c84

dev-libs/check/check-0.15.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="A unit test framework for C"
+HOMEPAGE="https://libcheck.github.io/check/"
+SRC_URI="https://github.com/libcheck/check/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc subunit test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="subunit? ( dev-python/subunit[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	sys-apps/texinfo"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+PATCHES=( "${FILESDIR}/check-0.14.0-r2-disable-automagic-dep.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Fix wrong libdir, probably caused by multilib
+	sed -i "s|\${libdir}|/usr/$(get_libdir)|g" check.pc.in || die "sed .pc failed."
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHECK_ENABLE_SUBUNIT=$(usex subunit ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+
+	if use doc && multilib_is_native_abi; then
+		cd "${S}"/doc/ || die "Failed to switch directories."
+		doxygen "." || die "Failed to run doxygen to generate docs."
+	fi
+}
+
+multilib_src_install_all() {
+	use doc && local HTML_DOCS=( "${S}"/doc/html/. )
+	einstalldocs
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}