app-misc/ddccontrol: bump

Remove sourceforge from metadata as it is not getting any updates anymore. Signed-off-by: Robin H. Johnson <[email protected]>
johu · Jul 1, 2023 · 43e4bbc · 43e4bbc
1 parent 789ce62
commit 43e4bbc
Show file tree

Hide file tree

Showing 4 changed files with 87 additions and 2 deletions.
diff --git a/app-misc/ddccontrol/Manifest b/app-misc/ddccontrol/Manifest
@@ -1 +1,2 @@
 DIST ddccontrol-0.6.0.tar.gz 180376 BLAKE2B d844f03ae4843a710a3a7143b1270656202c261b5e412822c49c2096c150052ddb6747b62f7c1d2404cffeb13af5ed604be915061b3fd339c8dcf66473bbd791 SHA512 49e857e8ef8f2ba87dc51056b9511ce55f3e6471222cd9171a324e2ee179b8c96a8f4d90c63bb379260ccc8e1d9653964f90748d6589d298ff2bbe6982efd3e2
+DIST ddccontrol-0.6.1.tar.gz 180407 BLAKE2B fba90502925320f3eb20e71498456e8b1135af9d67a78a74ec7b28d3d49a2841fcb77806a983c4231e8e97d07ef7fdf29b36145316f130ed8a529ef39ed4d104 SHA512 abc8940dcd651c25e1030bd4f5ae59774cfa08b22352a653140ec924cbcaa93855473385575636ec0cd51ea5f1871e2331ade592846eafddb7eae99f55ff1164
diff --git a/app-misc/ddccontrol/ddccontrol-0.6.0.ebuild b/app-misc/ddccontrol/ddccontrol-0.6.0.ebuild
@@ -6,7 +6,7 @@ EAPI=8
 inherit autotools
 
 DESCRIPTION="Control monitor parameters, like brightness, contrast, RGB color levels via DDC"
-HOMEPAGE="https://ddccontrol.sourceforge.net/"
+HOMEPAGE="https://github.com/ddccontrol/ddccontrol/"
 SRC_URI="https://github.com/ddccontrol/ddccontrol/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-2+"

diff --git a/app-misc/ddccontrol/ddccontrol-0.6.1.ebuild b/app-misc/ddccontrol/ddccontrol-0.6.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Control monitor parameters, like brightness, contrast, RGB color levels via DDC"
+HOMEPAGE="https://github.com/ddccontrol/ddccontrol/"
+SRC_URI="https://github.com/ddccontrol/ddccontrol/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc gtk nls +pci static-libs"
+
+RDEPEND="app-misc/ddccontrol-db
+ dev-libs/glib:2
+ dev-libs/libxml2:2
+ app-arch/xz-utils
+ gtk? (
+ dev-libs/atk
+ media-libs/fontconfig
+ media-libs/freetype
+ media-libs/harfbuzz:=
+ x11-libs/cairo
+ x11-libs/gdk-pixbuf:2
+ x11-libs/gtk+:2
+ x11-libs/pango
+ )
+ pci? ( sys-apps/pciutils )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-perl/XML-Parser
+ dev-util/gdbus-codegen
+ dev-util/intltool
+ sys-kernel/linux-headers
+ doc? (
+ >=app-text/docbook-xsl-stylesheets-1.65.1
+ app-text/htmltidy
+ >=dev-libs/libxslt-1.1.6
+ )
+ nls? ( sys-devel/gettext )"
+
+src_prepare() {
+ # ppc/ppc64 do not have inb/outb/ioperm
+ # they also do not have (sys|asm)/io.h
+ if ! use amd64 && ! use x86 ; then
+ local card
+ for card in sis intel810 ; do
+ sed -r -i \
+ -e "/${card}.Po/d" \
+ -e "s~${card}[^[:space:]]*~ ~g" \
+ src/ddcpci/Makefile.{am,ini} || die
+ done
+ sed -i \
+ -e '/sis_/d' \
+ -e '/i810_/d' \
+ src/ddcpci/main.c || die
+ fi
+
+ default
+
+ ## Save for a rainy day or future patching
+ touch config.rpath ABOUT-NLS
+ eautoreconf
+ intltoolize --force || die "intltoolize failed"
+}
+
+src_configure() {
+ # amdadl broken, bug #527268
+ econf \
+ --htmldir='$(datarootdir)'/doc/${PF}/html \
+ --disable-gnome-applet \
+ --disable-amdadl \
+ $(use_enable doc) \
+ $(use_enable gtk gnome) \
+ $(use_enable nls) \
+ $(use_enable pci ddcpci) \
+ $(use_enable static-libs static)
+}
+
+src_install() {
+ default
+ use static-libs || find "${ED}" -name '*.la' -delete
+}
diff --git a/app-misc/ddccontrol/metadata.xml b/app-misc/ddccontrol/metadata.xml
@@ -7,6 +7,5 @@
  </use>
  <upstream>
  <remote-id type="github">ddccontrol/ddccontrol</remote-id>
- <remote-id type="sourceforge">ddccontrol</remote-id>
  </upstream>
 </pkgmetadata>