games-simulation/openrct2: bump to version 0.3.1

Dropped for now arm64, since dev-cpp/nlohmann_json is not keyworded. Package-Manager: Portage-3.0.8, Repoman-3.0.1 Signed-off-by: Conrad Kostecki <[email protected]>
johu · Oct 3, 2020 · 4532894 · 4532894
1 parent 67b32ca
commit 4532894
Show file tree

Hide file tree

Showing 2 changed files with 170 additions and 0 deletions.
diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
@@ -1,4 +1,7 @@
 DIST openrct2-0.3.0.tar.gz 11754657 BLAKE2B 66d956fd85829bc6b4825a59db9f3a3eebbb1e4565a4c8afdb8c05d9d7b3f339f75ff1d9fbc0a0f48d3c0673ac3fc335fb6bec5fe458513de2a0611ccfa3d48d SHA512 585bcd7a077114dc5332b95cb44f7c689e47fcbd7cff7c2ab32a24253a4fd87f50e79f40f9428c79ea6bc6d8cd88019b4edfce88509c03bc2d43854926d21317
+DIST openrct2-0.3.1.tar.gz 11761818 BLAKE2B e89b6272d70d0f908f313efdff4f4788480ce14cf2872a8104a67b5e6283cb366d78d9a2f2692d9da627d06ee23a4632e4120d0437149e48f36b5a988bc5b674 SHA512 2a6027a28a26d9770a759296cfcf38290b44b90483113e93b8762403e1043dbe88c6666245155b4c7fc9d9122f44705b718cdc8dbc7b9d3888dc9036fd5928a1
 DIST openrct2-objects-1.0.16.zip 3056214 BLAKE2B 7d8d938ba20ce612f7845dce1038134ec60d7e17e0f7d78a67480ae1ae2e6f8dd043f266742acd2dbd8539390349a2dcd7b8c73859a3caef3b5cd8565a4ec1c7 SHA512 2a8696467320f7894330d0fbb4894dd6effb2d6844fcf643e1f8e15a7b0b45411a7c205b75a9e9d7ea0627bc70b7a7e1e2213e0f7db1c7b489ae8b485670dba5
+DIST openrct2-objects-1.0.17.zip 3106347 BLAKE2B d69df650f3d493d1d22ea9d6269fc18df121c64c0372dbcaf8fcee7ba81f9918e80c46e34b7d6ad4dcd3af9b7411e91fd8dc23499ee9b3ebcc269a4aed72d640 SHA512 3de4d2a58dbbf17d30296829edc520b089bb98457e5569578491f0750a95b172326bea6f153d4dcc2152736a32b2401d15c6cfa49ae3e95ec13bfcee24af2a5b
 DIST openrct2-replays-0.0.17.zip 1825315 BLAKE2B 9c22b52302c37abe5e802662eb4b6805fa3e229a71ab9f901b57eee30641ae4b86de9b1315476d158a3feb57c6be2a26c1ccca7c94328fe35bf57b46e2364c32 SHA512 103a8ba5b5b2dd76c18b642720d262553bb15ad26d59892f895327bf5e87b73e476b255af6556286faacb668aae49aa1ee29a14bcca2bb75d855383d12e60f4a
+DIST openrct2-replays-0.0.18.zip 1825295 BLAKE2B fb873fe235c1cc4b76b3d074a41be779f03561d92aa2e13870aca6de116910ae22589de9f5c57e65b3b6eb6f6d192f03d48c9f2e7a76ace81d4c5d14c19eb078 SHA512 5012f63c1b203e348e58168dedcbca3b170339dd65f4b63cbd31b145fc9b50160c2fb17b4e7e72972a1de807dffe82b846f360dfa16e5d5992d21d9fdbb3f948
 DIST openrct2-title-sequences-0.1.2c.zip 2980030 BLAKE2B f91168bea0a4f88a801c95ea45759e0d1c887a89c18dbbded5887d2914db7119dd65c231aa422e4f8a964a81d832eae05bffaa8b7908fac39a63792d082b53a0 SHA512 0e544d236d5f6ac7f68d75ba1f56f043c76c77676cbb92e6fdbf68a6ae2dc6c41dbdad6083ceec36b2f774bcdd99f64f28de73b208d6a39a8218a9e95502d46e
diff --git a/games-simulation/openrct2/openrct2-0.3.1.ebuild b/games-simulation/openrct2/openrct2-0.3.1.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_TS="title-sequences"
+MY_PV_OBJ="1.0.17"
+MY_PV_RPL="0.0.18"
+MY_PV_TS="0.1.2c"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+	https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+	https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+	test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated libressl +lightfx +opengl scripting test +truetype"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	dev-libs/jansson
+	dev-libs/libzip:=
+	media-libs/libpng:0=
+	net-misc/curl[ssl]
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2
+		media-libs/speexdsp
+		opengl? ( virtual/opengl )
+	)
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	scripting? ( dev-lang/duktape )
+	truetype? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+	)
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dedicated? (
+		acct-group/openrct2
+		acct-user/openrct2
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	dev-cpp/nlohmann_json
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2.4-include-additional-paths.patch"
+	"${FILESDIR}/${PN}-0.2.6-gtest-1.10.patch"
+)
+
+src_unpack() {
+	unpack "${P}".tar.gz
+
+	mkdir -p "${S}"/data/sequence || die
+	cd "${S}"/data/sequence || die
+	unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+	mkdir -p "${S}"/data/object || die
+	cd "${S}"/data/object || die
+	unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+	if use test; then
+		mkdir -p "${S}"/testdata/replays || die
+		cd "${S}"/testdata/replays || die
+		unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Don't treat warnings as errors.
+	sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	# Note: There is currently no support for Disord-RPC and Google Benchmark,
+	# as both packages do not exist in Gentoo, so support for them has been disabled.
+	local mycmakeargs=(
+		-DDISABLE_DISCORD_RPC=ON
+		-DDISABLE_GOOGLE_BENCHMARK=ON
+		-DDISABLE_GUI=$(usex dedicated)
+		-DDISABLE_HTTP=OFF
+		-DDISABLE_NETWORK=OFF
+		$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+		-DDISABLE_TTF=$(usex !truetype)
+		-DDOWNLOAD_OBJECTS=OFF
+		-DDOWNLOAD_REPLAYS=OFF
+		-DDOWNLOAD_TITLE_SEQUENCES=OFF
+		-DENABLE_LIGHTFX=$(usex lightfx)
+		-DENABLE_SCRIPTING=$(usex scripting)
+		-DOPENRCT2_USE_CCACHE=OFF
+		-DPORTABLE=OFF
+		-DSTATIC=OFF
+		$(usex test "-DSYSTEM_GTEST=ON" "")
+		-DWITH_TESTS=$(usex test)
+		-DUSE_MMAP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Since the tests need the OpenRCT2 data,
+	# we need to symlink them into the build directory,
+	# otherwise some tests will fail, as they don't find the OpenRCT2 data.
+	# It is currently not possible to override that path.
+	# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+	ln -s "${S}"/data "${BUILD_DIR}" || die
+
+	cmake_src_test
+}
+
+src_install() {
+	use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+	cmake_src_install
+
+	if use dedicated; then
+		newinitd "${FILESDIR}"/openrct2.initd openrct2
+		newconfd "${FILESDIR}"/openrct2.confd openrct2
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}