app-i18n/ibus-table: new upstream release

Signed-off-by: Akinori Hattori <[email protected]>

app-i18n/ibus-table/Manifest

@@ -1,2 +1,3 @@
 DIST ibus-table-1.16.12.tar.gz 1519559 BLAKE2B c0e236ae58cbcc7c52bc29f30f2be5ed02590bab96fb9866bb829986fef9e01964b3f4b55caa1d417840372b0c3c230a93713aa774272375b5cd21a2a851bba8 SHA512 edbbb4842a6b49cdf8a830187422b7042c47b9ddf4876eb114acdb1e449024a6f4f48d46cb97d4420d65dffc14b3e3e9400d31b92ac68ccd2e9a327151dcaa3f
 DIST ibus-table-1.16.13.tar.gz 1532633 BLAKE2B c47b7c1b523554993a007e6b4701d7ee92a000503004bdbc3832a8b3540bb440e9c51eee61f83fd04eb921cd84fedac84cb6b77effd305531aa8d43f980f275a SHA512 d060619c81ff3d610140593a47fed6b430f32f0e5927d824d36bd082d394e473f6d534f7b9b0d0100f878001b7e8b4384e1770c5e1887976cfe248bba5bb6318
+DIST ibus-table-1.16.14.tar.gz 1534056 BLAKE2B 512c1610e4e7096d25c5ff8678e0e91a4cae96ca7036dae0b33ef8f3461e0e6c89cddb35bcd0bf50c48d308d1b0831c02957863419ccbfba64182290a9567acb SHA512 a865c8913bee5e462ed8f3ba74a720b3eb37062ae762e3909827b660dc62d3055e6b90fd3c583487fb23edd2d9572d9eae201d7fbde889ec5cd8e5848b83291f

app-i18n/ibus-table/ibus-table-1.16.14.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Tables engines for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://github.com/kaio/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	python_fix_shebang .
+
+	default
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}