app-admin/bitwarden-desktop-bin: version bump 1.32.1

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Michael Palimaka <[email protected]>

app-admin/bitwarden-desktop-bin/Manifest

@@ -1,2 +1,3 @@
 DIST Bitwarden-1.28.3-amd64.deb 58747514 BLAKE2B 5d62084e89df9ac1b2f3b487d8594f5cd5e9fd411b46d95bc0310f27e772d4f7185507610c204f345f24defd5f87c954381c14427d4a7b69d51737b71cc61474 SHA512 7d061ae18a11c733a72fbb0e657c5f14d04054ae97720c3920d9641c880aea2de5638b908719a1fb4d8c23f32b49697cfa7994732441135007cdf2572bf41cfb
 DIST Bitwarden-1.30.0-amd64.deb 60998388 BLAKE2B 72731519bdf14153e0c7db85c200d8c67a07113f68078a22c29b2160ba49da0e3813676a2813a4fa62e8e927d375ed2c2eb43252a12435483fd998f22b720c60 SHA512 d44dea61c618bed9ddebbd7cf5cb76ea260e119486944ed9a8e252dc96b571a61216fcb0d7f570dd7eb0b6f50a5c6aac3148375145dd5cf6678993e7ff83f24b
+DIST Bitwarden-1.32.1-amd64.deb 72752286 BLAKE2B f7ea64bacb85820872c026d4f4bc6e7b70533bc64af85cea71beac4cf5da559a2178775a2eb31c805837ec5b7fc853c5c097fe3fa71bebf796ea165f62723a4b SHA512 514e9da98a4987d7a65e4b8a5f00fe9154a5e7558edc8d14360a1e7e21a24d4ad2ee82c38b029976d6671af991a82d54207cbfc73c7e246b7c18e5ddceb9394f

app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-1.32.1.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg-utils
+
+MY_PN="Bitwarden"
+
+DESCRIPTION="Bitwarden password manager desktop client"
+HOMEPAGE="https://bitwarden.com/"
+SRC_URI="https://github.com/bitwarden/desktop/releases/download/v${PV}/Bitwarden-${PV}-amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	app-crypt/libsecret
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib
+	sys-libs/glibc
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libxshmfence
+	x11-libs/libXtst
+	x11-libs/pango
+"
+IDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+"
+
+QA_PREBUILT="
+	opt/Bitwarden/*.so*
+	opt/Bitwarden/bitwarden
+	opt/Bitwarden/chrome-sandbox
+"
+
+src_install() {
+	insinto /opt
+	doins -r opt/${MY_PN}
+	fperms 755 /opt/Bitwarden/bitwarden
+	fperms 4755 /opt/Bitwarden/chrome-sandbox
+
+	domenu usr/share/applications/bitwarden.desktop
+
+	local x
+	for x in 16 32 48 64 256 512; do
+		doicon -s ${x} usr/share/icons/hicolor/${x}*/*
+	done
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}