media-gfx/eom: Bump to 1.24.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Adam Feldman <[email protected]>

media-gfx/eom/Manifest

@@ -1 +1,2 @@
 DIST eom-1.24.0.tar.xz 2433420 BLAKE2B 58f99ba3cf0df3594c459af691cc6ab281657facb49bc3b6101bec1718b165b72b882aabd9abac3c4981b547157aa64d2f24f174fccae06cdaa685728e49740c SHA512 17d26a9341cde0a86f8d8b65008f554398111d80f5d131441654bd9e907df9c9d696038e678aca8d7f4bd2923ff593f626735a3cc30451118818cdbebceb87ab
+DIST eom-1.24.1.tar.xz 2408284 BLAKE2B 70d660896dff42d5a91ea651697b50d4c90ced92023d5df48dfbed374c3777676f1f2dc99a0cb071a4eaa13353f31b11346136b963cf723397632cceafa64301 SHA512 70654b99f474d1b214cbbf8e799f82f3c38f47938df34cb5c8227c116b412364c568ae989b96d7082fb0d2fa319b3dba9b8dd499d19140a4d421bd09a46bffc0

media-gfx/eom/eom-1.24.1.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="The MATE image viewer"
+LICENSE="FDL-1.1+ GPL-2+ IJG LGPL-2+"
+SLOT="0"
+
+IUSE="X debug exif imagemagick +introspection jpeg lcms svg tiff xmp"
+
+COMMON_DEPEND="
+	dev-libs/atk
+	>=dev-libs/glib-2.52:2
+	>=dev-libs/libpeas-1.8.0[gtk]
+	>=dev-libs/libxml2-2:2
+	gnome-base/dconf
+	>=mate-base/mate-desktop-1.17.0
+	sys-libs/zlib
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?,jpeg?,tiff?]
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	>=x11-misc/shared-mime-info-0.20
+	exif? (
+		>=media-libs/libexif-0.6.14
+		virtual/jpeg:0
+	)
+	imagemagick? ( >=media-gfx/imagemagick-6.2.6 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	svg? ( >=gnome-base/librsvg-2.36.2:2 )
+	xmp? ( >=media-libs/exempi-1.99.5:2 )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+	!!media-gfx/mate-image-viewer
+"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/eom-1.24.0-add-gdk-includes.patch" )
+
+src_configure() {
+	mate_src_configure \
+		--enable-thumbnailer \
+		$(use_enable debug) \
+		$(use_enable introspection) \
+		$(use_with X x) \
+		$(use_with exif libexif) \
+		$(usex imagemagick \
+			--without-gdk-pixbuf-thumbnailer \
+			--with-gdk-pixbuf-thumbnailer \
+		) \
+		$(use_with jpeg libjpeg) \
+		$(use_with lcms cms) \
+		$(use_with svg librsvg) \
+		$(use_with xmp)
+}