kde-apps/dolphin-plugins-mercurial: 21.04.1 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

kde-apps/dolphin-plugins-mercurial/Manifest

@@ -1,2 +1,3 @@
 DIST dolphin-plugins-20.12.3.tar.xz 239340 BLAKE2B 141e5d2bb6190edaef98cec2a271e41b916966118300d69f4eb5e7da15e51730476f23a20312b76fca0fc1490501e83528b4f0cb62f9f6c64e4caf5ac5b2cd37 SHA512 1d5303e92d912bc80c5260263b081205d36372f1f15205ebd3e705697a114f8481edd1ad31004d7906c3088d43a74cb1e33dac6e1196c247e702a544d67db11b
 DIST dolphin-plugins-21.04.0.tar.xz 242608 BLAKE2B c12366f9a0d661e79b968ce375e2ea46dd8d90f322691755dc238d4dd08d07f6527711aa117fead2a3714d7f97c508e53c5ecd87a69c23c397e44033669fe5b1 SHA512 9f093133eba93615392a117f8184177f06bb117d4a3ad4691025ef26e4d83e251f966c157ae107f52447c78bf600ab586a175f57a02f78fec8e620aa5462138d
+DIST dolphin-plugins-21.04.1.tar.xz 247356 BLAKE2B 9dae16c07b7f1bf1bc3d33f2a9b32f52f18efb5cb73e82f4b35099dc38b9ecb31a1ec7f06c403d498b7f8f949de23f4ba2289c9efb7f67c19bff6d59595bafe9 SHA512 62ccbc3d8870f3352073299762d4ec6b8faf15a77a3530a6a93562ee776aded3a73a4d767523371c22fb7dec6c2ec8a1e9263ba2399a8fee7b20fc14c10ecf3a

kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.04.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-apps/dolphin-${PVCUT}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/ktexteditor-${KFMIN}:5
+ >=kde-frameworks/ktextwidgets-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+ dev-vcs/mercurial
+"
+
+src_prepare() {
+ ecm_src_prepare
+ # solid, qtdbus only required by mountiso
+ ecm_punt_bogus_dep Qt5 DBus
+ ecm_punt_bogus_dep KF5 Solid
+ # kxmlgui, qtnetwork only required by dropbox
+ ecm_punt_bogus_dep Qt5 Network
+ ecm_punt_bogus_dep KF5 XmlGui
+ # delete non-${PN} translations
+ if [[ ${KDE_BUILD_TYPE} = release ]]; then
+ find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_${MY_PLUGIN_NAME}=ON
+ -DBUILD_bazaar=OFF
+ -DBUILD_dropbox=OFF
+ -DBUILD_git=OFF
+ -DBUILD_mountiso=OFF
+ -DBUILD_svn=OFF
+ )
+ ecm_src_configure
+}
+
+src_install() {
+ ecm_src_install
+ rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}