kde-apps/ark: 22.08.2 version bump

Signed-off-by: Andreas Sturmlechner <[email protected]>

kde-apps/ark/Manifest

@@ -1,2 +1,3 @@
 DIST ark-22.04.3.tar.xz 2780848 BLAKE2B 8f08d0bb8a0263381e19d681c0e01f218e3886a5aab63dfe08f02ced984b5d6d2ed43ee8bdaf7ef6830940e57810cc434e3447ad85f54638927894d95c758190 SHA512 66f36b844bf526cd3b2044025f018257b65da11cb1fc116a4b131b790b446e0c4bc62ab76fc0684b61d8b0374583231531bf33caed37ab821c64b26fe48e57bc
 DIST ark-22.08.1.tar.xz 2784252 BLAKE2B 557dc7b22206ef8c2c52940361ddfa12bfa46233387594d991f8f38870bc435c2ae714672f8906c206cc8a933e106973791af91b3bf815dba0c3699943e4ebfc SHA512 8d18b5ec805502c26f31f4993db52dddf6f6c61ed23fd7b69402a9ac0fcbc9d38e178d6d9c053b19b33805716ddba49cbc8f7974e0fe0e3c55f12a5dc104fb22
+DIST ark-22.08.2.tar.xz 2785076 BLAKE2B 267d650153f0054fb433897870f0ecec95d28385e8690951925244a9018344fa8798dbf22c370d067c2729d42c28e5644664c7a6020dac0280e34b30fd034dc3 SHA512 a6bf4d94f772f842131a52842b4453b29213c18a5bc74e377385c186fbc4f6867f29b76b55cf3a6495f6c5a6b1ec123b57eb72bb5f0f07c1b0c9b7d7d677a6ba

kde-apps/ark/ark-22.08.2.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/ https://utils.kde.org/projects/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+ app-arch/libarchive:=[bzip2,lzma,zlib(+)]
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/karchive-${KFMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kcrash-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kitemmodels-${KFMIN}:5
+ >=kde-frameworks/kjobwidgets-${KFMIN}:5
+ >=kde-frameworks/kparts-${KFMIN}:5
+ >=kde-frameworks/kpty-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ sys-libs/zlib
+ zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+ >=dev-qt/qtconcurrent-${QTMIN}:5
+ test? ( >=dev-libs/libzip-1.6.0:= )
+"
+# app-arch/rar is binary only
+BDEPEND="
+ sys-devel/gettext
+ elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package zip LibZip)
+ )
+
+ ecm_src_configure
+}
+
+src_test() {
+ local myctestargs=(
+ # bug 822177: may segfault or hang indefinitely
+ -E "(kerfuffle-addtoarchivetest)"
+ )
+
+ ecm_src_test
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "rar archive creation/extraction" app-arch/rar
+ optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
+ optfeature "7-Zip archive support" app-arch/p7zip
+ optfeature "lrz archive support" app-arch/lrzip
+ optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
+ fi
+ ecm_pkg_postinst
+}