www-client/microsoft-edge: automated bump (98.0.1108.56)

Signed-off-by: Stephan Hartmann <[email protected]>

www-client/microsoft-edge/Manifest

@@ -1 +1,2 @@
 DIST microsoft-edge-stable_98.0.1108.55-1_amd64.deb 124169070 BLAKE2B 2bb007a0c719d1b68ce82af000171f24ea42b527cd2ded328164cd561e4646020a48b0e7037af68533ae0a26102311235cd78b6943511006ece7bdf3eb07b0db SHA512 a667b8ff061c8c1a8705d9581bd458a5011cd1da10307ebd66f20043bceeb1273449e992a25a87588e2062796dbd415eeb3952cc88fac267443129ae1555795a
+DIST microsoft-edge-stable_98.0.1108.56-1_amd64.deb 124147378 BLAKE2B 6568613b4e5df454f74bf8fc5b6f08c2a9a5bc2c7db8c895338591d3dcabb607cd6ffa258f6526fca3ae24234b2722cd7fe952bbc64cddeee531832bfb8261c9 SHA512 02134ab4ef21cfff63e6458b1d8ac9c5960fbfeb1810871b27be4bb5a09434187d77ebb8aa15040d7cf4b05b284dfbfb07055846d7b905af0d2774bfb205a55b

www-client/microsoft-edge/microsoft-edge-98.0.1108.56.ebuild

@@ -0,0 +1,116 @@
+# Copyright 2011-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit chromium-2 desktop pax-utils unpacker xdg
+
+DESCRIPTION="The web browser from Microsoft"
+HOMEPAGE="https://www.microsoft.com/en-us/edge"
+
+if [[ ${PN} == microsoft-edge ]]; then
+	MY_PN=${PN}-stable
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+MY_P="${MY_PN}_${PV}-1"
+
+SRC_URI="https://packages.microsoft.com/repos/edge/pool/main/m/${MY_PN}/${MY_P}_amd64.deb"
+
+LICENSE="microsoft-edge"
+SLOT="0"
+RESTRICT="bindist mirror strip"
+IUSE="+mip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	app-misc/ca-certificates
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl[ssl]
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[X]
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	mip? ( app-crypt/libsecret )
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/microsoft-edge.*\\.desktop"
+S=${WORKDIR}
+EDGE_HOME="opt/microsoft/msedge${PN#microsoft-edge}"
+
+pkg_nofetch() {
+	eerror "Please wait 24 hours and sync your tree before reporting a bug for microsoft-edge fetch failures."
+}
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "microsoft-edge only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	rm _gpgorigin || die
+
+	rm -r etc usr/share/menu || die
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+	gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
+	if [[ -L usr/share/man/man1/${PN}.1.gz ]]; then
+		rm usr/share/man/man1/${PN}.1.gz || die
+		dosym ${MY_PN}.1 usr/share/man/man1/${PN}.1
+	fi
+
+	local suffix=
+	[[ ${PN} == microsoft-edge-beta ]] && suffix=_beta
+	[[ ${PN} == microsoft-edge-dev ]] && suffix=_dev
+
+	local size
+	for size in 16 24 32 48 64 128 256 ; do
+		newicon -s ${size} "${EDGE_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
+	done
+
+	if ! use mip; then
+		rm "${EDGE_HOME}"/libmip_{core,protection_sdk}.so || die
+	fi
+
+	pax-mark m "${EDGE_HOME}/msedge"
+}