dev-ada/gnatcoll-bindings: bump to 2020

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Alfredo Tupone <[email protected]>

dev-ada/gnatcoll-bindings/Manifest

@@ -1 +1,2 @@
+DIST gnatcoll-bindings-20.0-20191009-1B2EA-src.tar.gz 139910 BLAKE2B 5441c277d5888b040930960ed656a1b1264c7de02834995c6040c891b99bf7e8773029b9f722d5a3ed30036e7bd441318989ce3f7839d47928af5f4f7c396f90 SHA512 2b723ba4327966dc06594ccff45da3a01f65b8f8b91130ddc44d1b727d23ccbfe35f082c73810418da9d0705f1dc8ca9b471748eecee42adce34be722a4a201b
 DIST gnatcoll-bindings-2019-20190430-1928C-src.tar.gz 138935 BLAKE2B c72398b51bf383b163ac10000c4dd5441334a6f24d7ad075d8115f25c030b43bc1dace6a1121e1e69add1eead93a5389aff09ef013deb4682ccb1d31bb85313f SHA512 6db1d35a1cdf5188001084750f7aa32b193768f8c3dfb6d7db8a8314c745fc054b0a6d2234a6dd64c5acd4b1bafffa7ce7f1080bd51fbb8bc88edfcc855b7a48

dev-ada/gnatcoll-bindings/gnatcoll-bindings-2020.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+ADA_COMPAT=( gnat_201{6,7,8,9} )
+inherit ada multilib multiprocessing python-single-r1
+
+MYP=${PN}-20.0-20191009-1B2EA
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="https://community.download.adacore.com/v1/3c54db553121bf88877e2f56ac4fca36765186eb?filename=${MYP}-src.tar.gz
+	-> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gmp iconv python readline +shared static-libs static-pic syslog"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	${ADA_DEPS}
+	dev-ada/gnatcoll-core[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}-src
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ada_pkg_setup
+}
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+		fi
+	done
+	if use iconv; then
+		sed -i \
+			-e "s:GNATCOLL_ICONV_BUILD:LIBRARY_TYPE:" \
+			"${D}"/usr/share/gpr/gnatcoll_iconv.gpr \
+			|| die
+	fi
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}