Skip to content

Commit

Permalink
net-im/prosody: bump to version 0.11.9
Browse files Browse the repository at this point in the history
Bug: https://bugs.gentoo.org/789969
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <[email protected]>
  • Loading branch information
ConiKost committed May 13, 2021
1 parent 3791046 commit 5a6d44e
Show file tree
Hide file tree
Showing 2 changed files with 103 additions and 0 deletions.
1 change: 1 addition & 0 deletions net-im/prosody/Manifest
Original file line number Diff line number Diff line change
@@ -1 +1,2 @@
DIST prosody-0.11.8.tar.gz 429762 BLAKE2B e7c945d0f99ed02cd54175f989241ee4731677600db39475365d3a4227afe2fa2b6f2075e3820fa9b7840d65014f43f786fa218a60765f7be319ddd7d30b67d4 SHA512 b0b7e1d3e41f47f0f88ad5b76444e4959b20f4c7a937f3cc605ba6ed5d92e713a3054dcb61ee6629063883a8f9ff1a03952893de4a0d840dcec4e5e42079eb57
DIST prosody-0.11.9.tar.gz 431647 BLAKE2B b6cf013a53c91675b50f601031b4843a826d011c4e06b06b27968413f4807a083811465b836531652fb47adc3bdb2ac82308a3c79953d80d6839ca23c669ab80 SHA512 fabbbbb1acb3de4ff01e3e8c6e9e4dc37cb161259f1649683a1f9d925ed9f1709e052bfc831cba3f1861a9cca599f2b725ee739bfcb57164d6f50ac07011b52a
102 changes: 102 additions & 0 deletions net-im/prosody/prosody-0.11.9.ebuild
Original file line number Diff line number Diff line change
@@ -0,0 +1,102 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

LUA_COMPAT=( lua5-{1..3} luajit )
LUA_REQ_USE="deprecated(+)"

inherit lua-single systemd tmpfiles toolchain-funcs

DESCRIPTION="Prosody is a modern XMPP communication server"
HOMEPAGE="https://prosody.im/"
SRC_URI="https://prosody.im/downloads/source/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
IUSE="icu +idn +libevent mysql postgres selinux +sqlite +ssl test +zlib"
REQUIRED_USE="
^^ ( icu idn )
${LUA_REQUIRED_USE}
"
RESTRICT="!test? ( test )"

DEPEND="
$(lua_gen_cond_dep 'dev-lua/luaexpat[${LUA_USEDEP}]')
$(lua_gen_cond_dep 'dev-lua/luafilesystem[${LUA_USEDEP}]')
$(lua_gen_cond_dep 'dev-lua/luasocket[${LUA_USEDEP}]')
net-im/jabber-base
icu? ( dev-libs/icu:= )
idn? ( net-dns/libidn:= )
libevent? ( $(lua_gen_cond_dep 'dev-lua/luaevent[${LUA_USEDEP}]') )
dev-libs/openssl:0=
lua_single_target_lua5-1? ( $(lua_gen_cond_dep 'dev-lua/lua-bit32[lua_targets_lua5-1(-)]') )
mysql? ( $(lua_gen_cond_dep 'dev-lua/luadbi[mysql,${LUA_USEDEP}]') )
postgres? ( $(lua_gen_cond_dep 'dev-lua/luadbi[postgres,${LUA_USEDEP}]') )
sqlite? ( $(lua_gen_cond_dep 'dev-lua/luadbi[sqlite,${LUA_USEDEP}]') )
ssl? ( $(lua_gen_cond_dep 'dev-lua/luasec[${LUA_USEDEP}]') )
zlib? ( $(lua_gen_cond_dep 'dev-lua/lua-zlib[${LUA_USEDEP}]') )
${LUA_DEPS}
"

RDEPEND="
${DEPEND}
selinux? ( sec-policy/selinux-jabber )
"

BDEPEND="
virtual/pkgconfig
test? ( $(lua_gen_cond_dep 'dev-lua/busted[${LUA_USEDEP}]') )
"

PATCHES=( "${FILESDIR}/${PN}-0.11.7-gentoo.patch" )

src_prepare() {
default

# Set correct plugin path for optional net-im/prosody-modules package
sed -e "s/GENTOO_LIBDIR/$(get_libdir)/g" -i prosody.cfg.lua.dist || die
}

src_configure() {
local myeconfargs=(
--add-cflags="${CFLAGS}"
--add-ldflags="${LDFLAGS}"
--c-compiler="$(tc-getCC)"
--datadir="${EPREFIX}/var/spool/jabber"
--idn-library="$(usex idn 'idn' 'icu')"
--libdir="${EPREFIX}/usr/$(get_libdir)"
--linker="$(tc-getCC)"
--lua-version="$(usex lua_single_target_luajit '5.1' $(ver_cut 1-2 $(lua_get_version)))"
--no-example-certs
--ostype="linux"
--prefix="${EPREFIX}/usr"
--runwith="${ELUA}"
--sysconfdir="${EPREFIX}/etc/jabber"
--with-lua-include="${EPREFIX}/$(lua_get_include_dir)"
--with-lua-lib="${EPREFIX}/$(lua_get_cmod_dir)"
)

# Since the configure script is handcrafted,
# and yells at unknown options, do not use 'econf'.
./configure "${myeconfargs[@]}" || die

rm makefile || die
mv GNUmakefile Makefile || die
}

src_install() {
default

keepdir /var/spool/jabber

newinitd "${FILESDIR}"/prosody.initd-r5 prosody
systemd_newunit "${FILESDIR}"/prosody.service-r2 prosody.service

newtmpfiles "${FILESDIR}"/prosody.tmpfilesd-r1 prosody.conf
}

pkg_postinst() {
tmpfiles_process prosody.conf
}

0 comments on commit 5a6d44e

Please sign in to comment.