dev-util/sysdig: Bump to 0.22.1

dev-util/sysdig/Manifest

@@ -1,2 +1,3 @@
 DIST sysdig-0.21.0.tar.gz 756010 BLAKE2B 0dfcc3e7f5c830e8b250e4edd9d470764ea6be25804fefbc59b020f208edc313a51b3fb783e538d2acb520c56ad7c8555f224fb90999c87b89125394a90d54a1 SHA512 73c516c9fccb504d4ccd37384aee37ece542d29f82d696acf7c90df18b3a1538faf8d2b29065eae1f3dca7c04c6c2dbe93ed9369bc1340216482c4af2f61d23a
 DIST sysdig-0.22.0.tar.gz 824519 BLAKE2B 7d46376f4f3c346fb6e9ce55552a0377aea6dc258ce3487b1e5a970a25721fca95d731d7313d1dc4b72dbefd9ac37e4050d7a934b8b9bdce027b5b6774ea1351 SHA512 599195bce77f4c2d3f62b11c00361420ab15da5fda4553486a7f812a1a464927cfa4ead36bf046fb1cecd3cf03e5d80a261d4571405d6bc309383bd2b4ad0204
+DIST sysdig-0.22.1.tar.gz 825171 BLAKE2B aa4836ed0be30fb3d8318b151c3f60586daaea15974558e7d81ba2da6d9c511bedc67fe8bc518697b6a268ea93bd112f64ae5772ef75c10d8b57d06e1468ff13 SHA512 e9f5ca594dc31832b4ea365a624208f5319add1480cfe9fb3d0e960757229fbe6ce46b906a390a667147ae1a7c0a31fd7ffeb9a1a0b376376530d4f60f397453

dev-util/sysdig/sysdig-0.22.1.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}